单片机 汇编 LED数码管动态显示

Question

OUTBIT equ 08002h ; 位控制口
OUTSEG equ 08004h ; 段控制口
IN equ 08001h ; 键盘读入口

LEDBuf equ 60h ; 显示缓冲
Num equ 70h ; 显示的数据
DelayT equ 75h ;
ljmp Start

LEDMAP: ; 八段管显示码
db 3fh, 06h, 5bh, 4fh, 66h, 6dh, 7dh, 07h
db 7fh, 6fh, 77h, 7ch, 39h, 5eh, 79h, 71h

Delay: ; 延时子程序
mov r7, #0
DelayLoop:
djnz r7, DelayLoop
djnz r6, DelayLoop
ret

DisplayLED:
mov r0, #LEDBuf
mov r1, #6 ; 共 6个八段管
mov r2, #00100000b ; 从左边开始显示
Loop:
mov dptr, #OUTBIT
mov a, #0
movx @dptr, a ; 关所有八段管

mov a, @r0
mov dptr, #OUTSEG
movx @dptr,a
mov dptr, #OUTBIT
mov a, r2
movx @dptr, a ; 显示一位八段管

mov r6, #01
call Delay

mov a, r2 ; 显示下一位
rr a
mov r2, a

inc r0

djnz r1, Loop

mov dptr, #OUTBIT
mov a, #0
movx @dptr, a ; 关所有八段管
ret

Start:
mov sp, #40h
mov Num, #0
MLoop:
inc Num
mov a, Num
mov b, a
mov r0, #LEDBuf
FillBuf:
mov a, b
anl a, #0fh
mov dptr, #LEDMap
movc a, @a+dptr ; 数字转换成显示码
mov @r0,a ; 显示在码填入显示缓冲
inc r0
cjne r0, #LEDBuf+6, FillBuf

mov DelayT,#30
DispAgain:
call DisplayLED ; 显示
djnz DelayT,DispAgain

ljmp MLoop

end
初学者 老师给我的实验版LED数码管的源程序 看不太懂
谁帮我详细解释一下 能不能帮我分析一下电路是怎么接的

发邮箱也可以 828801399@163.com
51单片机

Answer 1

dbuf equ 30h ;置存储区首址
temp equ 40h ;置缓冲区首址
org 00h
mov 30h,#2 ;存入数据
mov 31h,#0
mov 32h,#1
mov 33h,#0
mov 34h,#7
mov 35h,#1
mov r0,#dbuf
mov r1,#temp
mov r2,#6 ;六位显示器
mov dptr,#segtab ;段码表首地址
dp00: mov a,@r0 ;取要显示的数据
movc a,@a+dptr ;查表取段码
mov @r1,a ;段码暂存
inc r1
inc r0
djnz r2,dp00
disp0: mov r0,#temp ;显示子程序
mov r1,#6 ;扫描6次
mov r2,#01h ;从第一位开始
dp01: mov a,@r0
mov p0,a ;段码输出
mov a,r2 ;取位码
mov p1,a ;位码输出
acall delay ;调用延时
mov a,r2
rl a
mov r2,a
inc r0
djnz r1,dp01
sjmp disp0
segtab: db 3fh,06h,5bh,4fh,66h
db 6dh,7dh,07h,7fh,6fh
delay: mov r4,#03h ;延时子程序
aa1: mov r5,0ffh
aa: djnz r5,aa
djnz r4,aa1
ret
end

Answer 2

所谓的动态显示就是：led灯按设定的循序不停的一个一个（一个数用一块八段管）数的输出显示，由于led灯的闪烁速度很快，而人的眼睛最多只能识别0.2秒间隙以上的变化。那么在人看来，不停闪烁的led管就像是静态显示一样。

图中，段控制和位控制分时复用P0口，选用两个锁存器573来分开段控制和位控制数据。

段控制：数码管显示的字形

位控制：哪个数码管显示（或者说控制字形送往哪个数码管）

注意：段控制是与所有数码管连接在一起的。（如果将位控制全开的话，数码管就变成了静态显示了，并且显示的数字也是一样的）。位控制是独立一个一个连接的。

Answer 3

已发送 请注意查收