VB分数加减乘除代码

Question

谁能给VB分数加减乘除代码?我一定加30分!
如: Text1 Text2
_____ + _____ = ??
Text2 Text3

Text1 Text2
_____ - _____ = ??
Text2 Text3

Text1 Text2
_____ * _____ = ??
Text2 Text3

Text1 Text2
_____ / _____ = ??
Text2 Text3

或者编一个算24的程序

Answer 1

还是分数的四则运算好做。
计算完，只有约分有点技术含量。

补充：
下面的“分数四则运算”需要控件（大小位置都不用管）：
1、6个textbox，分别是text1直到text6
2、3根line，分别是line1到line3
3、4个optionbutton，分别是option1到option4
4、2个command，分别是command1和command2

代码如下：
Option Explicit
Const 标题 = "分数四则运算"
Dim a As Long, b As Long, c As Long, d As Long
Dim 分母 As Long, 分子 As Long

Private Sub 初始化()
Text1 = ""
Text2 = ""
Text3 = ""
Text4 = ""
Text5.Visible = False
Text6.Visible = False
Line3.Visible = False
Option1.Value = False
Option2.Value = False
Option3.Value = False
Option4.Value = False
Command2.Enabled = False
Command1.Enabled = True
Command1.Default = True
End Sub

Private Sub Command1_Click()
On Error GoTo 超范围
a = CInt(Val(Text1))
Text1 = a
b = CInt(Val(Text2))
Text2 = b
c = CInt(Val(Text3))
Text3 = c
d = CInt(Val(Text4))
Text4 = d
If b = 0 Or d = 0 Then
MsgBox "分母不得为零！", vbOKOnly + vbExclamation, 标题
Exit Sub
End If
If Option1 Then
分母 = b * d
分子 = a * d + c * b
ElseIf Option2 Then
分母 = b * d
分子 = a * d - c * b
ElseIf Option3 Then
分母 = b * d
分子 = a * c
ElseIf Option4 Then
分母 = b * c
分子 = a * d
Else
MsgBox "你还没有选择要进行什么运算呢！", vbOKOnly + vbExclamation, 标题
Exit Sub
End If
Dim 成功 As Boolean, i As Integer, 终值 As Integer
Do While Not 成功
If 分母 < 9 Then
终值 = 分母
Else
终值 = Sqr(分母)
End If
For i = 2 To 终值
If (分母 Mod i) = 0 And (分子 Mod i) = 0 Then
分母 = 分母 / i
分子 = 分子 / i
Exit For
End If
Next i
If i > 终值 Then 成功 = True
Loop
Text6 = 分母
Text5 = 分子
If 分母 = 1 Then
Text5.Top = 990
Else
Text5.Top = 700
Line3.Visible = True
Text6.Visible = True
End If
Text5.Visible = True
Text1.Locked = True
Text2.Locked = True
Text3.Locked = True
Text3.Locked = True
Text5.Locked = True
Text6.Locked = True
Command2.Enabled = True
Command2.Default = True
Command1.Enabled = False
Exit Sub

超范围:
MsgBox "你输入的数太大了，我算得头都晕了！", vbOKOnly + vbInformation, 标题
End Sub

Private Sub Command2_Click()
Text1.Locked = False
Text2.Locked = False
Text3.Locked = False
Text3.Locked = False
Text5.Locked = False
Text6.Locked = False
初始化
End Sub

Private Sub Form_Load()
Me.Caption = 标题
Height = 3000
Width = 6500
Text1.Move 300, 700, 1500, 300
Line1.X1 = 270
Line1.Y1 = 1150
Line1.X2 = 1830
Line1.Y2 = 1150
Text2.Move 300, 1300, 1500, 300
Option1.Caption = "＋"
Option2.Caption = "－"
Option3.Caption = "×"
Option4.Caption = "÷"
Option1.Move 1920, 550, 600, 300
Option2.Move 1920, 850, 600, 300
Option3.Move 1920, 1150, 600, 300
Option4.Move 1920, 1450, 600, 300
Text3.Move 2550, 700, 1500, 300
Line2.X1 = 2520
Line2.Y1 = 1150
Line2.X2 = 4065
Line2.Y2 = 1150
Text4.Move 2550, 1300, 1500, 300
Command1.Caption = "＝"
Command1.Move 4110, 990, 300, 300
Text5.Move 4470, 700, 1500, 300
Line3.X1 = 4440
Line3.Y1 = 1150
Line3.X2 = 6000
Line3.Y2 = 1150
Text6.Move 4470, 1300, 1500, 300
初始化
Command2.Caption = "下一题"
Command2.Move 4000, 1800, 1200, 300
End Sub

Answer 2

一、把下面代码复制到模块中：
'====模块代码====
Function js(Bds As String) As Single
Dim MSCC As Object
Set MSCC = CreateObject("ScriptControl")
MSCC.Language = "VBScript"
js = MSCC.Eval(Bds)
Set MSCC = Nothing
End Function
二、程序调用举例：
比如：计算
Text1 Text2
_____ - _____ = ??
Text2 Text3
应该这样调用：
Private Sub Command1_Click()
Dim i As Single
i = js(Text1.text & "/" & text2.text)-js(Text2.text & "/" & text3.text)
msgbox "计算结果为：" & i
End Sub

Answer 3

a=val(inputbox("请输入数字a"))
b=val(inputbox("请输入数字b"))
text1.text=a+b
text2.text=a-b
text3.text=a*b
text4.text=a/b