汇编语言设计，急！

Question

子程序设计
一．实验目的
掌握循环程序设计的方法（两重性循环结构）
掌握正确分配与使用寄存器。
二．实验内容与要求
以GRADE为首地址的10个字的数组中保存有学生成绩。建立一个10个字的RNAK 数组，并根据GRADE中的学生成绩将学生名次填入RANK数组中（提示：一个学生的名次等于成绩高于等于该学生的人数加1）。
寄存器分配情况说明如下：
AX 存放当前被测学生的成绩
BX 存放当前被测学生的相对地址指针
CX 内循环计数值
DX 存放当前被测学生的名次计数值
SI 内循环测试时的地址指针
DI 外循环计数值

麻烦帮我设计一个！

Answer 1

;Copyright:wangtianxu
;File name:rank.asm
;Description:建立学生名次表rank
STACK1 SEGMENT
DW 32 DUP('S')
STACK1 ENDS
DATA SEGMENT
GRADE DW 89,90,60,57,78,83,96,99,73,89 ;数组
RANK DW 10 DUP(?) ;预留空间
CN DW ($-RANK)/2 ;元素个数
DATA ENDS
CODE SEGMENT
ASSUME CS:CODE,DS:DATA,SS:STACK1
MAIN PROC FAR
START:
MOV AX,DATA
mov DS,AX
MOV CX,10;设置循环次数为10
MOV BX,0;BX存放当前被处理的数据在数组中的索引值,初始化为0
CYCLE: ;外层循环起始
PUSH CX;保存循环计数(下面的POP CX用来恢复这个记数)
MOV AX,GRADE[BX];取出第BX个学生的成绩
MOV DX,0;存放当前处理的学生的名次,初始化为0
LEA SI,GRADE;取数组的起始片仪偏移值
MOV CX,10
NEXT:;内层循环
CMP AX,[SI];AX与[SI]比较
JG NOCOUNT;如果AX大,则跳过INC DX
INC DX;AX不大于DS:[SI],则DX自增一次
NOCOUNT:
ADD SI,2;使SI加2,以便指向下一个被比较的对象
LOOP NEXT;内层循环,CX不为0则跳到NEXT
MOV RANK[BX],DX;DX是第BX个学生的排名
POP CX;恢复外层循环的次数
ADD BX,2;指向下一个被处理的学生的成绩
LOOP CYCLE;外循环
MOV AH,4CH
INT 21H
MAIN ENDP
CODE ENDS
END START

参考的C语言代码（译成汇编与上面的代码不全相同，但是算法一样的）里面的变量为了和上面的汇编比较，都是用寄存器名命名的，但是请注意还是有许多区别，不要弄混了。
int grade[10] = {88,75,95,63,98,78,87,73,90,60};
int rank[10];
void main()
{
int ax,si,bx=0,dx;
int cx;//循环计数。为了模拟上面的CX，这里就只用一个变量cx。
int temp;
for(cx = 10;cx != 0; cx--)
{
temp = cx;
ax = grade[bx];
si = 0;
for(cx = 10;cx != 0; cx--) //内层循环，cx应该被初始化为10，这样ax才能和所有的学生比较.
{
if(ax<=grade[si]) //和自己比较时相等，满足，故dx自加1，这样循环结束时dx就是“比自己成绩高的人数+1”了，也就是名次。
dx++;
si += 1;
}
rank[bx] = dx;
bx += 1;
cx = temp;
}
}