紧急求救 8068汇编的几道程序题

Question

一，实验内容：通过输入字符（只能是+、 -、*、/中一个，否则为非法字符，给出出错提示并重新输入）选择对两个数据进行不同的运算。输入字符为q表示退出程序。
技术要点：运用dos功能调用中9号、1号中断进行编程。其中，1号功能调用输入参数是：AH中置功能号1。输出参数为：AL中置输入键盘对应的ASCII码。
二，，实验内容：先任意输入一个密码串（规定长度，如：7个字节），然后要求重新输入密码串，如果前后一致，则程序显示“correct”并退出，反之，显示“error，input again”并重新输入。
技术要点：运用9号功能调用进行信息提示，运用7号功能调用接收键盘字符但不回显，用2号功能调用将*号替代输入字符进行回显（每输入一个字符即调用一次2号功能调用）。在调用7号中断的同时要有顺序地将键盘输入字符写入预定存储空间，并将前后输入依次进行比较。
跪求那位高手给我写下程序。。100分送上完后追加200
输入的

Answer 1

第一题
; 本程序通过编译，运行正确
; 说明：本程序的重点在于对输入的四则运算符的判断和处理上，对两个数相应运算的溢出未作处理。
Code Segment
Assume CS:Code,DS:Code
CR equ 000DH
LF equ 000AH
KBBack equ 0008H
; －－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－
; 功能：显示指定地址（Str_Addr）的字符串
; 入口：
; Str_Addr＝字符串地址（要求在数据段）

; 用法: Output Str_Addr
; 用法举例：Output PromptStr

Output MACRO Str_Addr
lea dx,Str_Addr
mov ah,9
int 21h
EndM
; －－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－
; 功能：输出一个字符
; 入口：dl=要显示的字符
Output_Chr proc Near
push ax
mov ah,02h
int 21h
pop ax
ret
Output_Chr endp
; －－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－
; 功能：输出回车换行
Output_CTLF proc Near
push ax
push dx
mov ah,02h
mov dl,0dh
int 21h
mov dl,0ah
int 21h
pop dx
pop ax
ret
Output_CTLF endp
; －－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－
; 功能：取光标位置
; 入口：无
; 出口：DH=行号，DL=列号
GetCursor Proc Near
PUSH AX
PUSH BX
PUSH CX
XOR BX,BX
MOV AH,3
INT 10H
MOV Cursor_Row,DH
MOV Cursor_Col,DL
POP CX
POP BX
POP AX
RET
Cursor_Row DB ?
Cursor_Col DB ?
GetCursor EndP
; －－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－
; 功能：置光标位置
; 入口：Cursor_Row=行坐标; Cursor_Col: 列坐标)
SetCursor Proc Near
PUSH CX
PUSH BX
PUSH AX
MOV DH,Cursor_Row
MOV DL,Cursor_Col
XOR BX,BX
MOV AH,2
INT 10H
POP AX
POP BX
POP CX
RET
SetCursor EndP
; －－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－
; 功能：键盘输入一个指定位数的十进制数字，将其转换成二进制数并保存在指定的内存单元。
; 入口：@@Digits=数字位数；di=保存输入的数字首地址
; @@Type_Data=保存的数据类型，B=字节类型，W=字类型。
; 出口：转换后的二进制数保存在di所指的单元
Input_Digit Proc Near
push dx
push cx
push bx
push di
lea di,@@Save_Tmp
push di
cld
mov cl,@@Digits
xor ch,ch
push cx
@@Input: call GetCursor ;取光标位置
mov ah,1 ;从键盘接受一个字符
int 21h
cmp al,CR ;若键入的是回车，已经键入的数字不足N位
jz @@ASC_Dec ;转去处理已经键入的数字
cmp al,KBBack
jz @@KB_Back ;若是回空键，重新输入
cmp al,'0'
jb @@KBBack ;若低于数字'0'，重新输入
cmp al,'9'
ja @@KBBack ;若低于数字'9'，重新输入
jmp @@Save_Dig
@@KB_Back: dec Cursor_Col
inc cx
dec di
@@KBBack: call SetCursor ;置光标位置
jmp @@Input
@@Save_Dig: and al,0fh ;转换成二进制数
stosb ;保存
loop @@Input ;接受下一个数字
@@ASC_Dec: mov ax,cx
pop cx
pop si
sub cx,ax ;实际输入的数字位数
xor bp,bp
xor dx,dx
xor ax,ax
jcxz @@Save_Ret ;若直接回车，没有输入任何数字，按输入'0'处理
dec cx ;实际输入的数字位数减1，准备把输入的这一串数字转换成二进制数
jcxz @@One_Digit ;若输入的数字只有一位，转去直接保存这个二进制数
mov bx,10
@@Mul_Ten: lodsb
cbw
add ax,bp
mul bx
mov bp,ax
loop @@Mul_Ten
@@One_Digit:lodsb
cbw
add ax,bp
@@Save_Ret: pop di
cmp @@Type_Data,'B' ;字节类型？
jz $+5
stosw
jmp $+3
stosb
pop bx
pop cx
pop dx
ret
@@Digits db ? ;十进制数字位数
@@Type_Data db 'B' ;保存的数据类型。B=字节类型，W=字类型
@@Save_Tmp db 16 dup(?)
Input_Digit EndP
; －－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－
; 功能：把AX中的二进制无符号数转换成显式的十进制ASCII码，并送显示屏显示
; 入口：AX=二进制数
; 出口：在当前光标位置显示转换后的ASCII码数字
Dec_ASCII Proc Near
push dx
push bx
push di
mov bx,10
lea di,@@Temp_Save[6]
mov byte ptr [di],'$'
dec di
cld
@@Divide: xor dx,dx
div bx
or dl,30h
mov [di],dl
dec di
test ax,0ffffh
jnz @@Divide
inc di
push di
pop dx
mov ah,9
int 21h
pop di
pop bx
pop dx
ret
@@Temp_Save db 7 dup(?)
Dec_ASCII EndP
; －－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－
; 加法运算
Addition Proc Near
mov ax,Number1
call Dec_ASCII ;把AX中的二进制无符号数转换成显式的十进制ASCII码，并送显示屏显示
mov dl,'+'
call Output_Chr ;显示一个加号
mov ax,Number2
call Dec_ASCII ;显示第二个数
mov dl,'='
call Output_Chr ;显示一个等号
mov ax,Number1
add ax,Number2 ;Number1+Number2→AX
call Dec_ASCII ;显示和
ret
Addition EndP
; －－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－
; 减法运算
Subtration Proc Near
mov ax,Number1
call Dec_ASCII
mov dl,'-'
call Output_Chr ;显示一个减号
mov ax,Number2
call Dec_ASCII ;显示第二个数
mov dl,'='
call Output_Chr ;显示一个等号
mov ax,Number1
sub ax,Number2 ;Number1-Number2→AX
call Dec_ASCII ;显示差
ret
Subtration EndP
; －－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－
; 乘法运算（请事先算好了，否则，容易导致乘积超过16位寄存器能够表示的范围）
Multiple Proc Near
mov ax,Number1
call Dec_ASCII
mov dl,'*'
call Output_Chr ;显示一个乘号
mov ax,Number2
call Dec_ASCII ;显示第二个数
mov dl,'='
call Output_Chr ;显示一个等号
mov ax,Number1
mul Number2 ;Number1*Number2→AX
call Dec_ASCII ;显示乘积（假定乘积不超过16位寄存器能够表示的范围）
ret
Multiple EndP
; －－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－
; 除法运算
Period_Aft db 2 ;保留小数位数
Division Proc Near
mov ax,Number1
call Dec_ASCII
mov dl,'/'
call Output_Chr ;显示一个除号
mov ax,Number2
call Dec_ASCII ;显示第二个数
mov dl,'='
call Output_Chr ;显示一个等号
xor dx,dx
mov ax,Number1
div Number2 ;Number1/Number2→AX（商），DX（余数）
call Dec_ASCII ;显示商数的整数部分
test dx,0ffffh ;判断余数是否为0
jz Exit_Proc ;能够整除，结束程序
push dx
mov dl,'.'
call Output_Chr ;显示一个小数点
pop dx
mov bp,10 ;乘数
mov cl,Period_Aft ;保留小数位数
xor ch,ch
Dec_Frac: mov ax,dx ;余数不为0，处理小数部分
mul bp ;余数乘10，继续做除法
div Number2 ;除以除数，取商数作为结果的一位小数
push dx
or al,30h
mov dl,al
call Output_Chr ;显示一位小数
pop dx
test dx,0ffffh ;判断余数是否为0
jz Exit_Proc ;能够整除，结束程序
loop Dec_Frac
ret
Division EndP
; －－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－
Number1 dw ?
Number2 dw ?
prompt_One db 'Please the first number: $'
prompt_Two db 'Please the second number: $'
prompt_Chr db 'Please input a operator: $'
prompt_Err db 7,CR,LF,CR,LF,'Invalid operator!'
Press_Key db CR,LF,'Press any key to input again...$'
Operators db '+-*/'
Procedure dw Addition,Subtration,Multiple,Division
Start: push cs
pop ds
push cs
pop es ;使数据段、附加段与代码段同段
; －－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－
; 输入两个十进制数
Output prompt_One ;提示输入第一个数
mov @@Digits,4 ;十进制数字位数
mov @@Type_Data,'W' ;保存的数据类型。B=字节类型，W=字类型
lea di,Number1 ;变量Number1的地址
call Input_Digit ;从键盘接受一个N位数字
call Output_CTLF ;输出一个回车、换行
Output prompt_Two ;提示输入第一个数
lea di,Number2 ;变量Number1的地址
call Input_Digit ;从键盘接受一个N位数字
call Output_CTLF ;输出一个回车、换行
call Output_CTLF ;输出一个回车、换行
xor bx,bx
call GetCursor ;取当前光标位置
; －－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－
; 接收一个运算符，进行相应的运算
Input_Oper: call SetCursor ;设置光标位置
Output prompt_Chr ;提示输入一个运算符
mov ah,1
int 21h
mov ah,al
and ah,0dfh ;若为字母，转为大写
cmp ah,'Q'
jz Exit_Proc ;若输入的字符是：q或Q，结束程序
xor si,si ;有效运算符字符串字符下标
mov cx,4 ;4个运算符
Compare: cmp al,Operators[si]
jz Operating
inc si
loop Compare
Output prompt_Err ;提示输入一个运算符
@@Press_Key:mov ah,1
int 21h
xor bh,bh
mov ah,8 ;度光标位置的字符和属性
int 10h
mov bh,ah ;空行属性
mov ch,Cursor_Row ;窗口左上角行号
mov cl,Cursor_Col ;窗口左上角列号
mov dx,244fh ;窗口右下角坐标
mov al,dh
sub al,ch
mov ah,6 ;上滚窗口内容
int 10h
jmp Input_Oper ;重新输入
Operating: call Output_CTLF ;输出一个回车、换行
call Output_CTLF
shl si,1
call Procedure[si] ;调用相应的字程序
call Output_CTLF
Output Press_Key
jmp @@Press_Key
Exit_Proc: mov ah,4ch ;结束程序
int 21h
Code ENDS
END Start ;编译到此结束

第二题
; 本程序通过编译，运行正确
Code Segment
Assume CS:Code,DS:Code
CR equ 000DH
LF equ 000AH
KBBack equ 0008H
; －－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－
; 功能：显示指定地址（Str_Addr）的字符串
; 入口：
; Str_Addr＝字符串地址（要求在数据段）
; 用法: Output Str_Addr
; 用法举例：Output PromptStr
Output MACRO Str_Addr
lea dx,Str_Addr
mov ah,9
int 21h
EndM
; －－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－
; 功能：输出一个字符
; 入口：dl=要显示的字符
Output_Chr proc Near
push ax
mov ah,02h
int 21h
pop ax
ret
Output_Chr endp
; －－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－
; 功能：取光标位置
; 入口：无
; 出口：DH=行号，DL=列号
GetCursor Proc Near
PUSH AX
PUSH BX
PUSH CX
XOR BX,BX
MOV AH,3
INT 10H
MOV Cursor_Row,DH
MOV Cursor_Col,DL
POP CX
POP BX
POP AX
RET
Cursor_Row DB ?
Cursor_Col DB ?
GetCursor EndP
; －－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－
; 功能：置光标位置
; 入口：Cursor_Row=行坐标; Cursor_Col: 列坐标)
SetCursor Proc Near
PUSH CX
PUSH BX
PUSH AX
MOV DH,Cursor_Row
MOV DL,Cursor_Col
XOR BX,BX
MOV AH,2
INT 10H
POP AX
POP BX
POP CX
RET
SetCursor EndP
; －－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－
; 功能：输入指定长度的密码
; 入口：DX=提示信息地址，DI=密码输入缓冲区地址
Input_Code Proc Near
mov ah,9 ;提示输入密码
int 21h
mov cx,Code_Len ;密码串长度
cld
@@Input_Chr:call GetCursor ;取光标位置
mov ah,7 ;不带回显的直接控制台输入
int 21h
cmp al,KBBack
jz @@KB_Back ;若是回空键，重新输入
stosb ;保存接收的字符
mov dl,'*' ;用*代替输入的实际字符
call Output_Chr ;显示一个字符
loop @@Input_Chr ;下一个字符
ret
@@KB_Back: dec Cursor_Col
inc cx
dec di
@@KBBack: call SetCursor ;置光标位置
jmp @@Input_Chr
Input_Code EndP
; －－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－
Code_Len equ 6 ;密码串长度
prompt_One db 'Pass word: $'
prompt_Two db CR,LF,CR,LF,'Pass word again: $'
prompt_Cor db CR,LF,CR,LF,'correct. Press any key to exit...$'
prompt_Err db 7,CR,LF,CR,LF,'Error! Press any key to input again...$'
Start: push cs
pop ds
push cs
pop es ;使数据段、附加段与代码段同段
@@Input: lea dx,prompt_One ;输入密码提示信息地址
lea di,Pass_Word ;密码输入缓冲区地址
call Input_Code ;输入指定长度的密码
lea dx,prompt_Two ;再输入一次密码提示信息地址
call Input_Code ;输入指定长度的密码
lea si,Pass_Word ;密码输入缓冲区地址
mov di,si
mov cx,Code_Len ;密码串长度
add di,cx ;第二个密码串地址
Compare: lodsb
cmp al,[di]
jnz @@Error ;若有一个字符不等，则提示密码输入错误
inc di
loop Compare
Output prompt_Cor ;提示密码输入正确
mov ah,1
int 21h
jmp Exit_Proc
@@Error: Output prompt_Err ;提示密码输入错误
mov ah,1
int 21h
xor bh,bh
mov ah,8 ;度光标位置的字符和属性
int 10h
mov bh,ah ;空行属性
xor cx,cx ;窗口左上角坐标
mov dx,244fh ;窗口右下角坐标
mov ax,600h ;上滚窗口内容
int 10h
xor dx,dx
xor bx,bx
mov ah,2 ;设置光标位置
int 10h
jmp @@Input ;重新输入
Exit_Proc: mov ah,4ch ;结束程序
int 21h
Pass_Word: ;密码输入缓冲区
Code ENDS
END Start ;编译到此结束

Answer 2

汤叔~有你在我都没生意了~ ^-^

Answer 3

xiang