Excel中的VBA编程问题之如何以后接方式复制文件内容

Question

如题，比如有两个文件1 和2，其中：
1.TXT的内容为：
123
456
2.TXT的内容为：
321
654
我想把2.TXT的内容以后接的方式复制到1.TXT中,以达到内容如下的目的：
123
456
321
654
请问这样的命名该如何写呢？多谢了

Answer 1

按楼主的要求，03版EXCEL测试通过。不妨试试！
在VBE窗口中插入模块，粘贴如下代码：
Sub txta_txtb()
Const ForReading = 1, ForWriting = 2, ForAppending = 8, TristateFalse = 0

Set fso = CreateObject("Scripting.FileSystemObject")
Set fa = Application.FileDialog(msoFileDialogOpen)
If fa.Show = -1 Then
FileA = fa.SelectedItems(1)
Else '如果没有选择文件
MsgBox "没有选择文件，请重新操作！", , "txta_txtb"
Exit Sub '退出程序
End If
Set fb = Application.FileDialog(msoFileDialogOpen)
If fb.Show = -1 Then
FileB = fb.SelectedItems(1)
Else
MsgBox "没有选择文件，请重新操作！", , "txta_txtb"
Exit Sub
End If

Set sFile = fso.OpenTextFile(FileB, ForAppending, TristateFalse)
Open FileA For Input As #1
Do Until EOF(1)
Line Input #1, tmp
'sFile.WriteLine tmp & vbTab & vbCrLf
sFile.Write tmp & vbTab & vbCrLf
Loop
Close #1
sFile.Close

End Sub
注意：过程执行中，两次通过“打开”对话框选择文本文件。第1次选择的文件是被提取数据，第2次选择的文件是写入数据的文件。

Answer 2

Private Sub Command1_Click()
Dim tmp$, ntxt$
ntxt = ""

Open "C:\a.txt" For Input As #1
Do Until EOF(1)
Line Input #1, tmp
ntxt = ntxt & tmp & vbCrLf
Loop
Close #1

ntxt = ntxt & vbCrLf

Open "C:\b.txt" For Input As #1
Do Until EOF(1)
Line Input #1, tmp
ntxt = ntxt & tmp & vbCrLf
Loop
Close #1

Open "C:\n.txt" For Output As #1
Print #1, ntxt
Close #1

End Sub

Answer 3

Option Explicit
'fso方法'添加引用 Microsoft Script Runtime
Private Sub Command1_Click()

Dim fso As New FileSystemObject
Dim ts As TextStream
Dim fp As String
Dim str As String

fp = App.Path & "\"
Set ts = fso.OpenTextFile(fp & "2.txt", ForReading)
str = ts.ReadAll
ts.Close

Set ts = fso.OpenTextFile(fp & "1.txt", ForAppending)
ts.Write (str)
ts.Close

Set ts = Nothing
Set fso = Nothing

End Sub