DW CS4制作ASP分页，记录集是Recordset1，但是想实现数字分页，网上有好多代码，不知道怎么用，本人菜鸟！

Question

DW CS4制作ASP分页，记录集是Recordset1，已经加上了重复区域和记录集分页导航条了。请高手指点下，怎么改成数字分页！或者干脆怎么实现，说的要详细点，不要复制网上的代码，我找了很多，但就是不知道怎么用，小弟跪谢！！

Answer 1

<!--
ASP 数据分页代码，防百度数据分页，带数字导航
显示样式

首页 上一页 [11] [12] [13] [14] [15] [16] 下一页 尾页 页次:16/16页 共31条记录 2 条/每页

修改的网络上的一个分页代码，完善了因为数据量太多，导致分页数码过多的情况。
修改者：刘超
QQ号码：784406767
本代码仅供学习 如果有修改 请注明并发送一分给我 谢谢。邮箱784406767@qq.com 交流
-->

<%
'=====================================================================
Const Btn_First="<span style='text-decoration:none; font-size:12px'> 首页</span>" '定义第一页按钮显示样式
Const Btn_Prev="<span style='text-decoration:none; font-size:12px'> 上一页 </span>" '定义前一页按钮显示样式
Const Btn_Next="<span style='text-decoration:none; font-size:12px'> 下一页 </span>" '定义下一页按钮显示样式
Const Btn_Last="<span style='text-decoration:none; font-size:12px'> 尾页 " '定义最后一页按钮显示样式
Const XD_Align="center" '定义分页信息对齐方式
Const XD_Width="100%" '定义分页信息框大小
Class Xdownpage
Private XD_PageCount,XD_Conn,XD_Rs,XD_SQL,XD_PageSize,Str_errors,int_curpage,str_URL,int_totalPage,int_totalRecord
'=================================================================
'PageSize 属性
'设置每一页的分页大小
'=================================================================
Public Property Let PageSize(int_PageSize)
If IsNumeric(Int_Pagesize) Then
XD_PageSize=CLng(int_PageSize)
Else
str_error=str_error & "<span style='text-decoration:none; font-size:12px'>PageSize的参数不正确</span>"
ShowError()
End If
End Property
Public Property Get PageSize
If XD_PageSize="" or (not(IsNumeric(XD_PageSize))) Then
PageSize=10
Else
PageSize=XD_PageSize
End If
End Property
'=================================================================
'GetRS 属性
'返回分页后的记录集
'=================================================================
Public Property Get GetRs()
Set XD_Rs=Server.createobject("adodb.recordset")
XD_Rs.PageSize=PageSize
XD_Rs.Open XD_SQL,XD_Conn,1,1
If not(XD_Rs.eof and XD_RS.BOF) Then
If int_curpage>XD_RS.PageCount Then
int_curpage=XD_RS.PageCount
End If
XD_Rs.AbsolutePage=int_curpage
End If
Set GetRs=XD_RS
End Property
'================================================================
'GetConn 得到数据库连接
'================================================================
Public Property Let GetConn(obj_Conn)
Set XD_Conn=obj_Conn
End Property
'================================================================
'GetSQL 得到查询语句
'================================================================
Public Property Let GetSQL(str_sql)
XD_SQL=str_sql
End Property
'==================================================================
'Class_Initialize 类的初始化
'初始化当前页的值
'==================================================================
Private Sub Class_Initialize
'========================
'设定一些参数的黙认值
'========================
XD_PageSize=10 '设定分页的默认值为10
'========================
'获取当前面的值
'========================
If request("page")="" Then
int_curpage=1
ElseIf not(IsNumeric(request("page"))) Then
int_curpage=1
ElseIf CInt(Trim(request("page")))<1 Then
int_curpage=1
Else
Int_curpage=CInt(Trim(request("page")))
End If
End Sub
'====================================================================
'ShowPage 创建分页导航条
'有首页、前一页、下一页、末页、还有数字导航
'====================================================================
Public Sub ShowPage()
Dim str_tmp
int_totalRecord=XD_RS.RecordCount
If int_totalRecord<=0 Then
str_error=str_error & "<span style='text-decoration:none; font-size:12px'>总记录数为零，请输入数据</span>"
Call ShowError()
End If
If int_totalRecord<pagesize Then
int_TotalPage=1
Else
int_TotalPage=XD_RS.PageCount
If int_totalRecord mod PageSize =0 Then
int_TotalPage = int(int_TotalRecord / XD_PageSize )
Else
int_TotalPage = int(int_TotalRecord / XD_PageSize )+1
End If
End If
If Int_curpage>int_Totalpage Then
int_curpage=int_TotalPage
End If
'===============================================================================
'显示分页信息，各个模块根据自己要求更改显求位置
'===============================================================================
response.write "<table border=0 width="&XD_Width&" style='text-decoration:none; font-size:12px'><tr><td align="&XD_Align&">"
str_tmp=ShowFirstPrv
response.write str_tmp
str_tmp=showNumBtn
response.write str_tmp
str_tmp=ShowNextLast
response.write str_tmp
str_tmp=ShowPageInfo
response.write str_tmp
response.write "</td></tr></table>"
End Sub
'====================================================================
'ShowFirstPrv 显示首页、前一页
'====================================================================
Private Function ShowFirstPrv()
Dim Str_tmp,int_prvpage
If int_curpage=1 Then
str_tmp=Btn_First&""&Btn_Prev
Else
int_prvpage=int_curpage-1
str_tmp="<a href="&geturl&"1>"&Btn_First&"</a><a href="&geturl & int_prvpage &">"& Btn_Prev&"</a>"
End If
ShowFirstPrv=str_tmp
End Function
'====================================================================
'ShowNextLast 下一页、末页
'====================================================================
Private Function ShowNextLast()
Dim str_tmp,int_Nextpage
If Int_curpage>=int_totalpage Then
str_tmp=Btn_Next & "" & Btn_Last
Else
Int_NextPage=int_curpage+1
str_tmp="<a href="& geturl & int_NextPage &">"&Btn_Next&"</a><a href="&geturl & int_totalpage &">"& Btn_Last&"</a>"
End If
ShowNextLast=str_tmp
End Function
'====================================================================
'ShowNumBtn 数字导航
'====================================================================
Private Function showNumBtn()
Dim i,str_tmp
'For i=1 to int_totalpage

'==================
'
'控制每页显示的页码数
'
'==================
dim top ,foot

if int_curpage<=5 then
top=1
else
top=int_curpage-5
end if

if int_curpage<=int_totalpage-5 then
foot=int_curpage+5
else
foot=int_totalpage
end if

'===========
'数字导航
'===========
For i=top to foot

if int_curpage=i then
str_tmp=str_tmp & "<a style='text-decoration:none; font-size:12px' href="& geturl & i &"> [<span style='font-size:12px; color:#F00; font-weight:bolder'>"&i&"</span>] </a>"
else
str_tmp=str_tmp & "<a style='text-decoration:none; font-size:12px' href="& geturl & i &"> ["&i&"] </a>"
end if

Next

showNumBtn=str_tmp
End Function
'====================================================================
'ShowPageInfo 分页信息
'更据要求自行修改
'
'====================================================================
Private Function ShowPageInfo()
Dim str_tmp
str_tmp="页次:<span style='color:#F00'>"&int_curpage&"</span>/"&int_totalpage&"页 共"&int_totalrecord&"条记录 "&XD_PageSize&" 条/每页"
ShowPageInfo=str_tmp
End Function
'==================================================================
'GetURL 得到当前的URL
'更据URL参数不同，获取不同的结果
'==================================================================
Private Function GetURL()
Dim strurl,str_url,i,j,search_str,result_url
search_str="page="
strurl=Request.ServerVariables("URL")
Strurl=split(strurl,"/")
i=UBound(strurl,1)
'response.write i
'response.end
str_url=strurl(i)'得到当前页文件名
str_params=Request.ServerVariables("QUERY_STRING")
If str_params="" Then
result_url=str_url & "?page="
Else
If InstrRev(str_params,search_str)=0 Then
result_url=str_url & "?" & str_params &"&page="
Else
j=InstrRev(str_params,search_str)-2
If j=-1 Then
result_url=str_url & "?page="
Else
str_params=Left(str_params,j)
result_url=str_url & "?" & str_params &"&page="
End If
End If
End If
GetURL=result_url
End Function
Private Sub ShowError()
If str_Error <> "" Then
Response.Write("<font color=""#FF0000""><b>" & SW_Error & "</font>")
Response.End
End If
End Sub
End class
%>

======================

调用方法
=======================

<%

'=====================================================================
'PapgeSize 定义分页每一页的记录数
'GetRS 返回经过分页的Recordset此属性只读
'GetConn 得到数据库连接
'GetSQL 得到查询语句
'ShowPage 显示分页导航条,唯一的公用方法
'=====================================================================
'

'加入 <!- #include file="page.asp" -->

'数据链接就省略了

'数据读取开始
Set mypage=new xdownpage '创建对象
mypage.pagesize=10 '设置每一页的记录条数据为10条,注意与page.asp文件的XD_PageSize=10保持一致
mypage.getconn=conn '得到数据库连接
mypage.getsql="select * from System_AD where xs=1 order by id asc "
set rs=mypage.getrs() '返回Recordset

for i=1 to mypage.pagesize
if not rs.eof then
%>

要现实的数据
<%
rs.movenext
else
exit for
end if
next

%>

<%
'调用分页显示

mypage.showpage()
rs.close
set rs=nothing
%>