Vlookup函数最经典的12种用法太太太太太太太有用了

Answer 1

Vlookup函数的教程网上已非常多了，而贴近工作用的Vlookup函数应用示例却很少。今天给同学们带来一期Vlookup函数示例大全，希望能给大家的工作带来帮助。
一
【例1】查找个人信息
=VLOOKUP($B18,$C$7:$H$15,COLUMN(B1),0)
注：Colum(b1)的结果是2，当公式向右复制时可以生成3，4，5，..

二
【例2】合并两个表格
F2单元格公式
=VLOOKUP(B2,$B$14:$F$22,MATCH(F$1,$B$13:$F$13,0))
公式说明：用Match函数查找表1的标题在表2中的位置

三
【例3】让两个表格同类商品排序完全一样
F2单元格公式
=IFERROR(VLOOKUP($B2,$B$12:$D$16,COLUMN(A1),),””)
公式说明：IFERROR函数用来屏蔽错误值

四
【例4】制作工资条
=VLOOKUP($G96,$A$96:$E$104,COLUMN(B1),)
公式说明：根据序号从工资表中查找对应的信息

五
【例5】计算个人所得税
=(G28-3500)*VLOOKUP(G28-3500,C28:E34,2)-VLOOKUP(G28-3500,C28:E34,3)
公式说明：当Vlookup最后一个参数为1或省略时，查找为近似匹配。即查找比指定值小且最接近的值。

六
模糊查找产品名称（包含查找）
=VLOOKUP(“*”&F41&”*”,$B$41:$D$47,3,0)
注：*是通配符，代表任意多个字符
七
带特殊符合的字符查找
=VLOOKUP(SUBSTITUTE(F52,”~”,”~~”),B$52:C$56,2,0)
注：由于~ * ？在公式中有通配符用法，遇到被查找的字符串中含有这3个字符就用Substitute替换为~~、~*和~？

八
逆向查找
=VLOOKUP(G61,IF(,C61:C69,B61:B69),2,)
公式说明: 本公式只做了解，遇到逆向查找，建议使用Index+Match函数。
=INDEX(B60:B69,MATCH(G61,C60:C69,0))

九
【例9】16年与17年单价核对，表格核对（带通配符），结果显示多N 或 少N
=TEXT(VLOOKUP(SUBSTITUTE(B73,”*”,”~*”),$F$73:$G$92,2,)-C73,”少0.00;多0.00;”)
公式说明:Text可以设置数字显示的格式
十
【例10】Vlookup多条件查找
A =B &C
H =VLOOKUP(F &G ,A :D120,4,0)
公式说明：Vlookup也可以使用IF(的数组形式实现多条件查找，但运行效率太慢，所以建议使用辅助列连接再查找的方法。

十一
【例11】库存单价的监控。销售单价>库存单价时填充红色背景

设置方法：选取区域 – 条件格式 – 新建规则 – 使用公式确定… – 在下面框中输入公式：
=H2>VLOOKUP(F2,A:C,3,0)
最后点“格式”按钮设置填充色为红色

十二
【例12】银行存款最近30天到期提醒。表中要有某天汇总金额，也要有明细金额

设置方法：
步骤1 添加辅助列，根据到期日生成 到期日+序列（目的是对同一个日期编序号，方便Vlookup一对多查找）
=D2&”-“&COUNTIF(D$2:D2,D2)

步骤2 设置到期日公式，H2单元格输入=Today() ,H3=H2+1,然后H3公式向下复制

步骤3 设置求和公式，用来统计每个到期时需要还款的总金额
=SUMIF(D:D,H2,C:C)

步骤4 用Vlookup查找各行明细数据
J2单元格公式
=IFERROR(VLOOKUP($H2&”-“&J$1,$A:$D,2,0)&”:”&VLOOKUP($H2&”-“&J$1,$A:$D,3,0),””)
公式说明：这里把H列日期&第1行的数字作为查找内容，在A列中进行查找，然后返回 B列 & C列的数据，

如果你觉得有用，一定要帮助小会分享给更多需要的朋友们。