VISUAL FOXPRO编译时有什么条件

Answer 1

被编译的文件不能是正在编辑或使用的文件;

文件中的实不能有实例;

文件不能是只读的.

如果项目在编译中失败,可以尝试在命令窗口使用Compile对项目中的表单/过程/类型库/标签/报表/数据库各自单独编译以确定是因为哪个文件导致整个项目编译失败.

可以使用一段代码来完成这个工作.

下列代码适用于VFP 6.0版本

Local oFile,oCompile
m.oCompile = CreateObject('MyCompile')

For Each oFile In _VFP.ActiveProject.Files 
  If InList(Lower(JustExt(m.oFile.Name)),'scx','prg','vcx','lbx','frx','dbc') Then
    m.oCompile.Compile (m.oFile.Name)
  EndIf
Next

Define Class MyCompile As Session
  NowFile = ''
  Procedure Compile(cFile)
    This.NowFile = m.cFile
    Local cExt
    m.cExt = Lower(JustExt(m.cFile))
    Do Case
    Case m.cExt == 'scx'
      Compile Form (m.cFile)
    Case m.cExt == 'prg'
      Compile (m.cFile)
    Case m.cExt == 'vcx'
      Compile Classlib (m.cFile)
    Case m.cExt == 'lbx'
      Compile Label (m.cFile)
    Case m.cExt == 'frx'
      Compile Report (m.cFile)
    Case m.cExt == 'dbc'
      Compile Database (m.cFile)
    EndCase
  EndProc
  Procedure Error(nError, cMethod, nLine)
    ?'编译失败:' + This.NowFile
  EndProc
EndDefine

在VFP8开始有Try语句了,就简单多了:

Local oFile,cExt
For Each oFile In _VFP.ActiveProject.Files 
  m.cExt = Lower(JustExt(m.oFile.Name))
  Try
    Do Case
    Case m.cExt == 'scx'
      Compile Form (m.oFile.Name)
    Case m.cExt == 'prg'
      Compile (m.oFile.Name)
    Case m.cExt == 'vcx'
      Compile Classlib (m.oFile.Name)
    Case m.cExt == 'lbx'
      Compile Label (m.oFile.Name)
    Case m.cExt == 'frx'
      Compile Report (m.oFile.Name)
    Case m.cExt == 'dbc'
      Compile Database (m.oFile.Name)
    EndCase
  Catch
    ?'编译失败:' + m.oFile.Name
  EndTry
Next