请老师能否帮忙把通达信的资金流向公式改成选股公式？谢谢！

Question

想把这个公式里的出现黄色底部的所有股选出来。
公式说明:
1、出现黄色表示底部快到了，是相对的底部，不是真的底部，这要看你自己的分析了。
2、红色表示资金进的多，中间的一根黄色线表示穿透力，线越长越好。
3、蓝色表示资金流出的多少，流出越多越不好

{资金流向}
ZC_1:=IF(L<DYNAINFO(7),0,IF(H>DYNAINFO(7),DYNAINFO(7)-(DYNAINFO(7)-H+0.02)/(H-L+0.02),0));
ZC_2:=DMA(ZC_1,V/CAPITAL)*100;
出货:=IF(ZC_2>0 AND ZC_2>REF(ZC_2,1),ZC_2/20,0);
轴:0,COLOR00FF00;
PJJ:=DMA((H + L + C * 2) / 4,0.9);
JJ:=REF(EMA(PJJ,3),1);
QJJ:=VOL / ((H - L) * 2 - ABS(C - O));
XVL:=IF(C > O,QJJ * (H - L),IF(C < O,QJJ * (H - O + (C - L)),VOL / 2)) + IF(C > O,0 - QJJ * (H - C + (O - L)),IF(C < O,0 - QJJ * (H - L),0 - VOL / 2));
ZLL:=VOL / CAPITAL;
HSL1:=IF(ZLL > 10,10,ZLL);
HSL:=XVL / 20 / 1.15;
攻击流量:=HSL * 0.55 + REF(HSL,1) * 0.33 + REF(HSL,2) * 0.22;
GJJ:=EMA(攻击流量,8);
LLJX:=EMA(攻击流量,3);
流量:LLJX,COLORC875B7,COLORRED,NODRAW;
STICKLINE(流量 > 0,流量,0,2.3,0)COLOR0000FF;
STICKLINE(流量 < 0,流量,0,2.3,0),COLORFF4242;
流量基线:GJJ,COLOR00BBBB,COLORGREEN;
STICKLINE(HSL * 0.4 >= 0,HSL * 0.4 * 1.5,0,0,1)COLORYELLOW;
STICKLINE(HSL * 0.4 < 0,HSL * 0.4 * 1.5,0,0,1)COLORGREEN;
ZJLL:=REF(LLJX,1);
QZJJ:=(((LLJX - ZJLL) / ZJLL) * 100);
流量幅%:IF(((LLJX > 0) AND (ZJLL < 0)),ABS(QZJJ),IF((((LLJX < 0) AND (ZJLL < 0)) AND (LLJX < ZJLL)),(0 - QZJJ),QZJJ))COLORMAGENTA,NODRAW;
力度:HSL / 1000,COLOR9B37FF,COLORRED,NODRAW;
周流量:SUM(LLJX,5),COLORFFBFDF,COLORMAGENTA,NODRAW;
BB:=REF(周流量,1);
ZQZJJ:=(周流量-BB)/BB*100;
周幅%:IF(周流量>0 AND BB<0,ABS(ZQZJJ),IF(周流量<0 AND BB<0 AND 周流量<BB,-ZQZJJ,ZQZJJ))COLORMAGENTA,NODRAW;
VARQ1:=REF((LOW+OPEN+CLOSE+HIGH)/4,1);
VARQ2:=SMA(ABS(LOW-VARQ1),13,1)/SMA(MAX(LOW-VARQ1,0),10,1);
VARQ3:=EMA(VARQ2,10);
VARQ4:=LLV(LOW,33);
VARQ5:=EMA(IF(LOW<=VARQ4,VARQ3,0),3)*100;
主力进场:STICKLINE(VARQ5>REF(VARQ5,1) AND 出货<=0,0,VARQ5,7,0 ),COLOR00FFFF;

Answer 1

{通达信测试通过黄底出现}
ZC_1:=IF(L<DYNAINFO(7),0,IF(H>DYNAINFO(7),DYNAINFO(7)-(DYNAINFO(7)-H+0.02)/(H-L+0.02),0));
ZC_2:=DMA(ZC_1,V/CAPITAL)*100;
出货:=IF(ZC_2>0 AND ZC_2>REF(ZC_2,1),ZC_2/20,0);
VARQ1:=REF((LOW+OPEN+CLOSE+HIGH)/4,1);
VARQ2:=SMA(ABS(LOW-VARQ1),13,1)/SMA(MAX(LOW-VARQ1,0),10,1);
VARQ3:=EMA(VARQ2,10);
VARQ4:=LLV(LOW,33);
VARQ5:=EMA(IF(LOW<=VARQ4,VARQ3,0),3)*100;
黄色底出现:VARQ5>REF(VARQ5,1) AND 出货<=0;

Answer 2

第一个主力进，大盘资金进场上涨
第二个N内净流入上涨,所编成一个条件预警
1:
V1:=(C*2+H+L)/4*10;
V2:=EMA(V1,13)-EMA(V1,34);
V3:=EMA(V2,5);
V4:=2*(V2-V3)*5.5;
主力进:=V4>=0;
V5:=(HHV(INDEXH,8)-INDEXC)/(HHV(INDEXH,8)-LLV(INDEXL,8))*8;
V6:=EMA(3*V5-2*SMA(V5,18,1),5);
V7:=(INDEXC-LLV(INDEXL,8))/(HHV(INDEXH,8)-LLV(INDEXL,8))*10;
V8:=(INDEXC*2+INDEXH+INDEXL)/4;
V9:=EMA(V8,13)-EMA(V8,34);
VA:=EMA(V9,3);
VB:=(V9-VA)/2;
大盘资金进场:=VB>=0;

AA:=VOL/((HIGH-LOW)*2-ABS(CLOSE-OPEN));
买量:=IF(CLOSE>OPEN,AA*(HIGH-LOW),IF(CLOSE<OPEN,AA*((HIGH-OPEN)+(CLOSE-LOW)),VOL/2)),LINETHICK0,COLORRED;
卖量:=IF(CLOSE>OPEN,0-AA*((HIGH-CLOSE)+(OPEN-LOW)),IF(CLOSE<OPEN,0-AA*(HIGH-LOW),0-VOL/2)),LINETHICK0,COLORCYAN;
进出量:=买量+卖量;

N日内净流入:=SUM(进出量,N);
流入:=N日内净流入>REF(N日内净流入,1);

XG:主力进>REF(主力进,1) OR 大盘资金进场>REF( 大盘资金进场,1) OR 流入;

2:

V1:=(C*2+H+L)/4*10;
V2:=EMA(V1,13)-EMA(V1,34);
V3:=EMA(V2,5);
V4:=2*(V2-V3)*5.5;
主力进:=V4>=0;
V5:=(HHV(INDEXH,8)-INDEXC)/(HHV(INDEXH,8)-LLV(INDEXL,8))*8;
V6:=EMA(3*V5-2*SMA(V5,18,1),5);
V7:=(INDEXC-LLV(INDEXL,8))/(HHV(INDEXH,8)-LLV(INDEXL,8))*10;
V8:=(INDEXC*2+INDEXH+INDEXL)/4;
V9:=EMA(V8,13)-EMA(V8,34);
VA:=EMA(V9,3);
VB:=(V9-VA)/2;
大盘资金进场:=VB>=0;

AA:=VOL/((HIGH-LOW)*2-ABS(CLOSE-OPEN));
买量:=IF(CLOSE>OPEN,AA*(HIGH-LOW),IF(CLOSE<OPEN,AA*((HIGH-OPEN)+(CLOSE-LOW)),VOL/2)),LINETHICK0,COLORRED;
卖量:=IF(CLOSE>OPEN,0-AA*((HIGH-CLOSE)+(OPEN-LOW)),IF(CLOSE<OPEN,0-AA*(HIGH-LOW),0-VOL/2)),LINETHICK0,COLORCYAN;
进出量:=买量+卖量;

N日内净流入:=SUM(进出量,N);
流入:=N日内净流入>REF(N日内净流入,1);

XG:主力进>REF(主力进,1) OR 大盘资金进场<REF( 大盘资金进场,1) OR 流入;

Answer 3

我就随口一说，千万别往心里去啊。7250

Answer 4

ZC_1:=IF(L
DYNAINFO(7),DYNAINFO(7)-(DYNAINFO(7)-H+0.02)/(H-L+0.02),0));
ZC_2:=DMA(ZC_1,V/CAPITAL)*100;
出货:=IF(ZC_2>0 AND ZC_2>REF(ZC_2,1),ZC_2/20,0);
VARQ1:=REF((LOW+OPEN+CLOSE+HIGH)/4,1);
VARQ2:=SMA(ABS(LOW-VARQ1),13,1)/SMA(MAX(LOW-VARQ1,0),10,1);
VARQ3:=EMA(VARQ2,10);
VARQ4:=LLV(LOW,33);
VARQ5:=EMA(IF(LOW
REF(VARQ5,1) AND 出货<=0;
XG:T1=1 AND REF(T1,1)=0;