用汇编编写一个关于数据的程序~·急！

Question

功能描述：
1. 从键盘输入20个数据（以十进制或十六进制输入均可），统计其中正数和负数的个数并显示出来（以十进制或十六进制显示均可）。
2． 求其中的最小偶数并显示出来。
3. 对输入的20个数按从小到大进行排序并显示出来。
注意：从键盘输入十进制数据的程序见参考资料1（沈美明）p199
从键盘输入十六进制数据的程序见参考资料1（沈美明）p225
但都需要加上对负号的处理。为了简单，也可以不从键盘输入数据，直接在数据段定义一些固定数据即可。
显示数据程序见参考资料1（沈美明）p161
希望能用比较简单的汇编语言，我只是一个初级学者，所以谢谢大家回答··~感激不尽·~

Answer 1

说明：输入、输出均为十进制数

; 本程序在MASMPlus 1.2集成环境下通过编译，经过调试，运行正确。
Code Segment
Assume CS:Code,DS:Code
; －－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－
; 功能：显示指定地址（Str_Addr）的字符串
; 入口：
; Str_Addr＝字符串地址（要求在数据段）
; 用法: Output Str_Addr
; 用法举例：Output PromptStr
Output MACRO Str_Addr
lea dx,Str_Addr
mov ah,9
int 21h
EndM
; －－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－
; 功能：在当前光标位置显示一个字符
; 入口：dl=要显示的字符
Output_Chr proc Near
push ax
mov ah,02h
int 21h
pop ax
ret
Output_Chr Endp
; －－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－
; 功能：把AX中的二进制无符号数转换成显式的十进制ASCII码，并送显示屏显示
; 入口：AX=二进制数
; 出口：在当前光标位置显示转换后的ASCII码数字
Unsi_Dec_ASCII Proc Near
push ds
push cs
pop ds
push cs
pop es
push dx
push bx
push di
mov bx,10
lea di,@@Temp_SaveU[5]
mov BYTE ptr [di],'$'
dec di
cld
@@Divide_U: xor dx,dx
div bx
or dl,30h
mov [di],dl
dec di
test ax,0ffffh
jnz @@Divide_U
inc di
push di
pop dx
mov ah,9
int 21h
pop di
pop bx
pop dx
pop ds
ret
@@Temp_SaveU db 6 dup(?)
Unsi_Dec_ASCII EndP
; －－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－
; 功能：把AX中的二进制有符号数转换成显式的十进制ASCII码，并送显示屏显示
; 入口：AX=二进制数
; 出口：在当前光标位置显示转换后的ASCII码数字
Sign_Dec_ASCII Proc Near
push ds
push cs
pop ds
push cs
pop es
push dx
push bx
push di
test ah,80h
jz @@Tran_ASCII
neg ax
push ax
mov dl,'-'
mov ah,2
int 21h
pop ax
@@Tran_ASCII: mov bx,10
lea di,@@Temp_SaveS[5]
mov BYTE ptr [di],'$'
dec di
cld
@@Divide_S: xor dx,dx
div bx
or dl,30h
mov [di],dl
dec di
test ax,0ffffh
jnz @@Divide_S
inc di
push di
pop dx
mov ah,9
int 21h
pop di
pop bx
pop dx
pop ds
ret
@@Temp_SaveS db 6 dup(?)
Sign_Dec_ASCII EndP
; －－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－
Buffer db 23,-69,-89,35,-46,57,-68,79,-51,-81,98,-43,56,-67,123,-98,102,-87,-91,-100
Counter equ $-Buffer ;数据个数
Prompt_Str1 db 'The positives: $' ;显示正数个数，提示信息
Prompt_Str2 db 13,10,'The negatives: $' ;显示负数个数，提示信息
Prompt_Str3 db 13,10,'The minimum even: $' ;显示最小偶数，提示信息
Prompt_Str4 db 13,10,13,10,'The increased: $',13,10 ;显示升序排序后的结果，提示信息
Press_Key db 13,10,13,10,'The complated. Press any key to exit...$'
Start: push cs
pop ds
push cs
pop es
; －－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－
; 统计正数、负数个数，求最小偶数
lea si,Buffer ;取数组变量地址
mov cx,Counter ;元素个数
xor bx,bx ;BH=正数个数，BL=负数个数
xor ah,ah ;最小偶数初值
cld
@@Statics: lodsb ;读入一个元素
test al,80h ;是否正数？
jnz $+6 ;不是
inc bh ;是，正数计数
jmp $+4
inc bl ;负数计数
test al,1 ;偶数？
jnz $+8 ;不是
cmp ah,al ;当前最小偶数<=当前元素？
jle $+4 ;是，不更新
mov ah,al ;更新最小偶数
loop @@Statics
push ax
Output Prompt_Str1 ;提示显示正数个数
mov al,bh
xor ah,ah
call Unsi_Dec_ASCII ;把AX中的二进制无符号数转换成显式的十进制ASCII码，并送显示屏显示
Output Prompt_Str2 ;提示显示负数个数
mov al,bl
xor ah,ah
call Unsi_Dec_ASCII
Output Prompt_Str3 ;提示显示最小偶数
pop ax
xchg ah,al
cbw ;扩展为字
call Sign_Dec_ASCII
; －－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－
; 用冒泡排序法将数组元素升序排序，显示排序结果
lea si,Buffer ;取数组变量地址
mov cx,Counter ;元素个数
dec cx ;准备用冒泡排序法排序
@@Sorting: push cx ;入栈保存外循环次数
push si ;入栈保存数组地址
@@Compare: push si
pop di ;当前数组元素地址赋给目的变址寄存器，以备交换之用
lodsb ;读入当前字数据给AX
cmp al,[si] ;当前字数据与相邻的下一个字数据相比较
jle $+5 ;若小于或等于，不作数据交换，处理下一个数组元素
xchg al,[si] ;若大于，交换数据
stosb ;保存数值较小者
loop @@Compare ;处理下一个数组元素
pop si ;数组地址出栈
pop cx ;外循环次数出栈
loop @@Sorting ;下一趟比较
Output Prompt_Str4 ;提示显示升序排序后的结果
lea si,Buffer ;取数组变量地址
mov cx,Counter ;元素个数
@@List_Table: lodsb
cbw ;扩展为字
call Sign_Dec_ASCII
mov dl,20h
call Output_Chr ;在当前光标位置显示一个字符
loop @@List_Table
; －－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－
Exit_Proc: Output Press_Key ;提示操作完成，按任意键结束程序
mov ah,1
int 21h
mov ah,4ch ;结束程序
int 21h
Code ENDS
END Start ;编译到此结束

Answer 2

又是老汤