请帮我解释解释这个vb代码的意思

Question

最好是每一句都解释一下，有些语句看不懂，谢谢
Dim x1 As Long, x2 As Long, x3 As Long, x4 As Long
Dim y1 As Long, y2 As Long, y3 As Long, y4 As Long
Dim d1 As Long, d2 As Long, d3 As Long, d4 As Long
Dim icolor As Long
Dim a As Single
Const Lft = 300
Const Rgt = 6000
Const Tp = 300
Const Btm = 6000
Private Sub Command1_Click()
Timer1.Enabled = True
End Sub
Private Sub Form_Load()
x1 = Lft: y1 = 2700: d1 = 4
x2 = 2400: y2 = Tp: d2 = 3
x3 = 4200: y3 = Btm: d3 = 1
x4 = Rgt: y4 = 3600: d4 = 2
Randomize
icolor = 255
End Sub
Sub DrawLines()
Picture1.Line (x1, y1)-(x2, y2)
Picture1.Line (x2, y2)-(x3, y3)
Picture1.Line (x3, y3)-(x4, y4)
Picture1.Line (x4, y4)-(x1, y1)
End Sub

Private Sub Timer1_Timer()
Randomize
a = 1 / Rnd
Picture1.ForeColor = RGB(icolor, icolor * Rnd, icolor * (1 - Rnd))
Picture1.DrawWidth = a
Picture1.ForeColor = RGB(icolor, icolor * Rnd, icolor * (1 - Rnd))
Picture1.Cls
movepoint x1, y1, d1
movepoint x2, y2, d2
movepoint x3, y3, d3
movepoint x4, y4, d4
DrawLines
End Sub
Sub movepoint(ByRef px, ByRef py, ByRef d)
Const Spd As Long = 120
Select Case d
Case 1
px = px + Rnd * Spd
If px > Rgt Then px = Rgt: d = d + 1
Case 2
py = py - Rnd * Spd
If py < Tp Then py = Tp: d = d + 1
Case 3
px = px - Rnd * Spd
If px < Lft Then px = Lft: d = d + 1
Case 4
py = py + Rnd * Spd
If py > Btm Then py = Btm: d = d - 3
End Select
End Sub

Private Sub Command2_Click()
Dim key As Variant
key = InputBox("请输入密码")
If key = 123 Then
Timer1.Enabled = False
Else
MsgBox " 密码错误"
Timer1.Enabled = False
End If
End Sub
这是一个屏保的程序

Answer 1

你把代码粘贴到VB里先看看运行效果，就是一个类似蝴蝶结的图形不停的在转
仔细观察，其实就是靠不断的变换4个顶点的位置来实现的

'保存那4个点的坐标
Dim x1 As Long, x2 As Long, x3 As Long, x4 As Long
Dim y1 As Long, y2 As Long, y3 As Long, y4 As Long

'这4个变量控制4个点运动方向的
Dim d1 As Long, d2 As Long, d3 As Long, d4 As Long

'决定线色
Dim icolor As Long

'决定线宽(说实话这个地方处理的不好)
Dim a As Single

'4个点运动限制到这个矩形范围内
Const Lft = 300
Const Rgt = 6000
Const Tp = 300
Const Btm = 6000

Private Sub Command1_Click()
Timer1.Enabled = True
End Sub

'初始化顶点的位置X,Y
'每个点有上下左右4个运动方向，d1，d2这几个变量取不同的值，表示不同的运动方向
Private Sub Form_Load()
x1 = Lft: y1 = 2700: d1 = 4
x2 = 2400: y2 = Tp: d2 = 3
x3 = 4200: y3 = Btm: d3 = 1
x4 = Rgt: y4 = 3600: d4 = 2

'重置随机数发生器种子
Randomize
icolor = 255
End Sub

'需要在4个顶点之间连4条线，大概是下面这个样子，平着两条，交叉两条
'1-2
' ×
'3-4

Sub DrawLines()
Picture1.Line (x1, y1)-(x2, y2)
Picture1.Line (x2, y2)-(x3, y3)
Picture1.Line (x3, y3)-(x4, y4)
Picture1.Line (x4, y4)-(x1, y1)
End Sub

'这里确定线色和线宽，然后画线
Private Sub Timer1_Timer()
Randomize
a = 1 / Rnd
Picture1.ForeColor = RGB(icolor, icolor * Rnd, icolor * (1 - Rnd))
Picture1.DrawWidth = a
Picture1.ForeColor = RGB(icolor, icolor * Rnd, icolor * (1 - Rnd))
Picture1.Cls
movepoint x1, y1, d1
movepoint x2, y2, d2
movepoint x3, y3, d3
movepoint x4, y4, d4
DrawLines
End Sub

'这是程序的关键处，控制顶点位置的改变
Sub movepoint(ByRef px, ByRef py, ByRef d)
'顶点运动的速度，这个值越大，每次变化的就越大
Const Spd As Long = 120

'd用来控制运动方向，比如处于下方的点一直向右运动，如果碰到右边界，就会转为向上运动，运动到上方后触碰到上边界，转而向左运动；类推
Select Case d
'd = 1时候，代表正在向右运动
Case 1
'横坐标增加
px = px + Rnd * Spd
'到达右边界，转而向上运动
If px > Rgt Then px = Rgt: d = d + 1

'下面的类似
Case 2
py = py - Rnd * Spd
If py < Tp Then py = Tp: d = d + 1
Case 3
px = px - Rnd * Spd
If px < Lft Then px = Lft: d = d + 1
Case 4
py = py + Rnd * Spd
If py > Btm Then py = Btm: d = d - 3
End Select
End Sub

'这一部分简单，自己看吧
Private Sub Command2_Click()
Dim key As Variant
key = InputBox("请输入密码")
If key = 123 Then
Timer1.Enabled = False
Else
MsgBox " 密码错误"
Timer1.Enabled = False
End If
End Sub