关于汇编语言？

Question

初学汇编，还无法完全看懂下面程序，求高手给分析一下。
http://hi.baidu.com/紫色鱼尾/blog/item/0baa42d64f927dc850da4b0e.html
程序在我空间里了

Answer 1

我把重要的语句做一下注释吧，希望对你有帮助

SECOND EQU 30H ；EQU相当于“=”，即定义second与地址单元30H等同
MINITE EQU 31H
HOUR EQU 32H
HOURK BIT P0.0 ；BIT是定义 位，即用HOURK代替P0.0口
MINITEK BIT P0.1
SECONDK BIT P0.2
DISPBUF EQU 40H
DISPBIT EQU 48H
T2SCNTA EQU 49H
T2SCNTB EQU 4AH
TEMP EQU 4BH

ORG 00H
LJMP START
ORG 0BH
LJMP I NT_T0
START: MOV SECOND,#00H ；将数值00H送入地址为30H的存储单元
MOV MINITE,#00H
MOV HOUR,#12
MOV DISPBIT,#00H
MOV T2SCNTA,#00H
MOV T2SCNTB,#00H
MOV TEMP,#0FEH ；付初值
LCALL DISP ；点亮第一位数码管
MOV TMOD,#01H ；设置T0为工作方式1，定时
MOV TH0,#(65536-2000) / 256 ；设置计数初值，计数2000次，即2ms
MOV TL0,#(65536-2000) MOD 256
SETB TR0 ；给TR0高电平1，即启动T0
SETB ET0 ；开定时器0中断
SETB EA ；开总中断
WT: JB SECONDK,NK1 ；判断 SECONDK中的直接位是否为1，为1跳转到NK1处执行，为0顺序执行
LCALL DELY10MS ；调用10MS延时程序，延时。
JB SECONDK,NK1 ；再次判断
INC SECOND ； SECOND中的数据自加1
MOV A,SECOND ；将SECOND中的数据再送入累加器A
CJNE A,#60,NS60 ；60与累加器A中的数值比较，不相等则跳转到NS60处执行，即判断是否到了60秒
MOV SECOND,#00H ；重新付初值
NS60: LCALL DISP ；调用数码管显示程序，显示秒
JNB SECONDK,$ ；直接位为0时原地跳转等待，为1顺序执行
NK1: JB MINITEK,NK2
LCALL DELY10MS
JB MINITEK,NK2
INC MINITE
MOV A,MINITE
CJNE A,#60,NM60 ；判断是否到了60分钟
MOV MINITE,#00H
NM60: LCALL DISP ；显示分
JNB MINITEK,$
NK2: JB HOURK,NK3
LCALL DELY10MS
JB HOURK,NK3
INC HOUR
MOV A,HOUR
CJNE A,#24,NH24 ；判断是否计满到24小时
MOV HOUR,#00H ；付初值
NH24: LCALL DISP ；显示时
JNB HOURK,$
NK3: LJMP WT ；长跳转到WT处，从新循环
DELY10MS: ；延时子程序
MOV R6,#10
D1: MOV R7,#248
DJNZ R7,$
DJNZ R6,D1
RET
DISP: ；显示子程序
MOV A,#DISPBUF
ADD A,#8
DEC A
MOV R1,A
MOV A,HOUR
MOV B,#10 ；用除以10的方法将2位数转换为十位和个位
DIV AB ；A中为十位数，B中为个位数
MOV @R1,A
DEC R1
MOV A,B
MOV @R1,A
DEC R1
MOV A,#10
MOV @R1,A
DEC R1
MOV A,MINITE
MOV B,#10
DIV AB
MOV @R1,A
DEC R1
MOV A,B
MOV @R1,A
DEC R1
MOV A,#10
MOV @R1,A
DEC R1
MOV A,SECOND
MOV B,#10
DIV AB
MOV @R1,A
DEC R1
MOV A,B
MOV @R1,A
DEC R1
RET
INT_T0: ；中断服务程序
MOV TH0,#(65536-2000) / 256
MOV TL0,#(65536-2000) MOD 256
MOV A,#DISPBUF
ADD A,DISPBIT
MOV R0,A
MOV A,@R0
MOV DPTR,#TABLE ；取数据表首地址
MOVC A,@A+DPTR
MOV P2,A ；送P2口显示
MOV A,DISPBIT
MOV DPTR,#TAB
MOVC A,@A+DPTR
MOV P1,A
INC DISPBIT
MOV A,DISPBIT
CJNE A,#08H,KNA 八个LED都亮过顺序执行
MOV DISPBIT,#00H
KNA: INC T2SCNTA
MOV A,T2SCNTA
CJNE A,#100,DONE
MOV T2SCNTA,#00H
INC T2SCNTB
MOV A,T2SCNTB
CJNE A,#05H,DONE ；5*100*2ms=1s
MOV T2SCNTB,#00H
INC SECOND
MOV A,SECOND
CJNE A,#60,NEXT
MOV SECOND,#00H
INC MINITE
MOV A,MINITE
CJNE A,#60,NEXT
MOV MINITE,#00H
INC HOUR
MOV A,HOUR
CJNE A,#24,NEXT
MOV HOUR,#00H
NEXT: LCALL DISP
DONE: RETI ；中断返回
TABLE: DB 3FH,06H,5BH,4FH,66H,6DH,7DH,07H,7FH,6FH,40H ；0—9显示段码
TAB: DB 0FEH,0FDH,0FBH,0F7H,0EFH,0DFH,0BFH,07FH ；数码管位选码
END

辛苦注释，希望给点分撒，呵呵，关键是希望对你有些帮助。