谁能帮忙编一个 显示ASCII码字符表 的汇编程序啊？

Question

显示ASCII码字符表
具体要求：
1）显示简易数字菜单
2）显示ASCII码字符表（20H-FFH）

这个是具体要求 希望高手帮助。

Answer 1

DATA SEGMENT
MENU DB '1--Show ASCII(20H-FFH) 2--Exit:','$'
BLANKLINE DB 80 DUP(' '),'$'
BUFF DB 3 DUP(?);用来存ASCII码值对应的字符串
DASH DB '-','$'
TAB DB ' ','$'
ASCII DB 20H
DATA ENDS

PRTSTR MACRO X;输出字符串
LEA DX,X
MOV AH,09H
INT 21H
ENDM

SETXY MACRO X,Y;设置光标位置，X=行，Y=列
XOR BH,BH
MOV AH,02H
MOV DH,X
MOV DL,Y
INT 10H
ENDM

EMPTYBUFF MACRO;清空ASCII码串
CLD
MOV AL,'$'
LEA DI,BUFF
MOV CX,3
REP STOSB
ENDM

TRANBUFF MACRO;转化ASCII码串
LOCAL L1,L2,L3,L4
CLD
MOV AL,ASCII
XOR AH,AH
MOV BL,16
DIV BL

LEA DI,BUFF
CMP AL,0AH
JB L1
ADD AL,37H
JMP L2
L1:
ADD AL,30H
L2:
STOSB
MOV AL,AH
CMP AL,0AH
JB L3
ADD AL,37H
JMP L4
L3:
ADD AL,30H
L4:
STOSB
ENDM

CODE SEGMENT
ASSUME CS:CODE,DS:DATA,ES:DATA
START:
MOV AX,DATA
MOV DS,AX
MOV ES,AX

;设置80×25黑白字符显示模式
MOV AH,00H
MOV AL,02H
INT 10H

@@:
SETXY 0,0
PRTSTR BLANKLINE
SETXY 0,0
PRTSTR MENU;输出菜单

MOV AH,01H
INT 21H;获得用户输入

CMP AL,'1'
JB @B
CMP AL,'2'
JA @B

JZ DONE

SETXY 1,0
L1:
CMP ASCII,0
JZ @B
EMPTYBUFF
TRANBUFF
PRTSTR BUFF
PRTSTR DASH
MOV AH,02H
MOV DL,ASCII
INT 21H
PRTSTR TAB
INC BYTE PTR ASCII
JMP L1

DONE:
MOV AX,4C00H
INT 21H
CODE ENDS
END START