VBA中textbox添加右键菜单功能！

Question

我在excel中做了一个窗体，里面添加了textbox控件，但是在输入的时候比如我想复制粘贴，点击右键没有反应，按ctrl+c等快捷键好用，我现在想在textbox里面添加单击右键弹出菜单的功能，方便复制粘贴剪切等的操作，请问代码应该怎么写？放在哪里？求高人，在线等！

Answer 1

给你看一下  蓝色幻想的一个程序事例  ，代码放窗体的加载程序里面

Sub 添加快捷菜单()
 Dim mypup As CommandBar
 Dim com As CommandBarButton
 Dim x
 删除命令
 Set mypup = Application.CommandBars.Add(Name:="ABC", Position:=msoBarPopup)
   For x = 1 To 4
    Set com = mypup.Controls.Add
     com.Caption = Choose(x, "兰色幻想", "小妖", "小佩", "展翅")
     '这4个是加的按钮的名字， 可以改成你自己的， 比如复制粘贴等
     
     com.FaceId = 17 + x
     com.OnAction = "A"
     '这句是指定的宏的名字， 可以改成你自己的宏， 比如复制 ，粘贴功能宏
   Next x
End Sub

Sub 删除命令()
  Application.CommandBars("ABC").Delete
End Sub

Answer 2

首先，添加一个模块，粘贴下面的代码：
Sub 添加()

Dim aa As CommandBar
Dim bb As CommandBarControl
On Error Resume Next
CommandBars("abc").Delete
On Error GoTo 0
Set aa = CommandBars.Add(Name:="abc", Position:=msoBarPopup, Temporary:=True)
With aa
Set bb = .Controls.Add(Type:=msoControlButton)
With bb
.Caption = "复 制"
.OnAction = "fuzhi"
End With
Set bb = .Controls.Add(Type:=msoControlButton)
With bb
.Caption = "剪 切"
.OnAction = "jianqie"
End With
Set bb = .Controls.Add(Type:=msoControlButton)
With bb
.Caption = "粘 贴"
.OnAction = "zhantie"
End With
Set bb = .Controls.Add(Type:=msoControlButton)
With bb
.Caption = "清 除"
.OnAction = "qingchu"
End With

End With
aa.ShowPopup
End Sub
Private Sub fuzhi()
Application.SendKeys "^c", True
End Sub
Private Sub jianqie()
Application.SendKeys "^x", True
End Sub
Private Sub zhantie()
Application.SendKeys "^v", True
End Sub
Private Sub qingchu()
Application.SendKeys "{del}", True
End Sub
然后添加textbox1的代码
Private Sub TextBox1_MouseUp(ByVal Button As Integer, ByVal Shift As Integer, ByVal X As Single, ByVal Y As Single)
If Button = xlSecondaryButton Then
添加
CommandBars("abc").Delete
End If
End Sub

Answer 3

我也想知道，我用
Application.CommandBars("Control Toolbox").ShowPopup X, Y
提示错误。有没有人知道，help一下。