这段汇编语言大概是什么意思

Question

ORG 0000H

LJMP 0100H

ORG 0003H

LJMP 0300H

ORG 000BH

LJMP 0400H

ORG 0013H

LJMP 0500H

ORG 0100H

MAIN:MOV P2,#0FFH

MOV TMOD,#01H ；定时器T0，方式1，定时50ms

MOV TH0,#3CH

MOV TL0,#0B0H

MOV DPTR,#TAB ；表首址送DPTR

MOV R0,#00H ；0.1s计数值

MOV R1,#00H ；1s计数值

MOV R2,#00H ；10s计数值

MOV R5,#02H ；50ms计数值

MOV TCON,#05H ；外部中断0和1下降沿有效

MOV IE,#87H ；开外部中断0、1和定时器T0中断

DIS: MOV A,R2 ；10s位显示

MOVC A,@A+DPTR

MOV P1,A

SETB P2.0

LCALL DLY

CLR P2.0

MOV A,R1 ；1s位显示

MOVC A,@A+DPTR

MOV P1,A

SETB P2.1

CLR P2.3 ；显示小数点位

LCALL DLY

CLR P2.1

SETB P2.3

MOV A,R0 ；0.1s位显示

MOVC A,@A+DPTR

MOV P1,A

SETB P2.2

LCALL DLY

CLR P2.2

LCALL DLY ；消隐程序

LJMP DIS

TAB: DB 0Xc0,0Xf9,0Xa4,0Xb0,0X99 ；共阳极0~9

DB 0X92,0X82,0Xf8,0X80,0X90

DLY: MOV R3,#14H ；10ms延时程序

D1: MOV R4,#0F8H

DJNZ R4,$

DJNZ R3,D1

RET

ORG 0300H

STT: MOV R0,#00H ；外部中断0程序，重装R0、R1、R2

MOV R1,#00H

MOV R2,#00H

SETB TR0 ；启动定时器T0

RETI

ORG 0500H

STP: CLR TR0 ；外部中断1程序，停止T0

RETI

ORG 0400H

T50: CLR TR0 ；定时器T0中断程序

MOV TH0,#3CH ；重装定时初值

MOV TL0,#0B0H

DJNZ R5,EXT ；是否计时100ms？

MOV R5,#02H

INC R0

CMS: CJNE R0,#0AH,CSL ；0.1s位计数值=10？

MOV R0,#00H

INC R1

CSL: CJNE R1,#0AH,CSH ；1s位计数值=10？

MOV R1,#00H

INC R2

CSH: CJNE R2,#0AH,EXT ；10s位计数值=10？

MOV R2,#00H

EXT: SETB TR0

RETI

END

Answer 1

用定时器计数器方式 计时并显示
P1口线一般连接LED，或者数码管
依次显示10s,1s,0.1s的计数值，例如100ms时，数码管依次显示 0，0，1
1s时，依次显示0，1，0。满10进位

Answer 2

是个秒表。
三位数字显示：十位、个位、0.1秒，最大显示99.9秒；
两个按键：一个启动秒表，从00.0开始计时、一个停止。

Answer 3

a a a a

Answer 4

哇，好多啊!!!!!!!