写一程序，要求按什么键就在数码管上显示其键值

Question

用汇编语言，0对应00h，1 对应01h，。。。a对应0ah

Answer 1

;*********************************************************************************

;Copyright(c)2010, GUILIN UNIVERSITY OF ELECTRONIC TECHNOLOGY

;All rights reserved

;

;实验任务:用AT89S51的并行口P1接4×4矩阵键盘，以P1.0－P1.3作列输入线，以P1.4－P1.7作行输出线.

;         在数码管上显示每个按键的"0－F"序号,使用使共阳码管显示对应的键值.

;

;********************************************************************************

;********************************************************************************

;程序初始化

;********************************************************************************         

          LEDOUT    EQU       P2

          KEYMATRIX EQU       P1

          

          SCANCODE  EQU       R2

          KEYCODE   EQU       R3

          COUNT     EQU       R4

          KEYCOUNT  EQU       R5

          

          ROWCOUNT  DATA      30H

          LINECOUNT DATA      31H

          

          KEYFLAG   EQU       F0

          

          ORG       0000H

          AJMP      START

          ORG       0030H

;********************************************************************************

;主程序

;********************************************************************************

START:    MOV       LEDOUT,#0FFH

          MOV       SCANCODE,#0EFH

          MOV       KEYCODE,#0

          MOV       COUNT,#0

          MOV       KEYCOUNT,#0

          MOV       ROWCOUNT,#0

          CLR       KEYFLAG

          

LOOP:     MOV       KEYMATRIX,SCANCODE

          MOV       KEYCODE,KEYMATRIX

          MOV       A,KEYCODE

          ANL       A,#0FH

          CJNE      A,#0FH,REMOVESHAKE

          AJMP      ROWSCAN                       ;如果没有按键按下，则不停的行扫描

REMOVESHAKE:

          ACALL     DEL10MS                       ;按键消抖

          MOV       KEYMATRIX,SCANCODE

          MOV       KEYCODE,KEYMATRIX

          MOV       A,KEYCODE

          ANL       A,#0FH

          CJNE      A,#0FH,KEYPRESSED

          AJMP      ROWSCAN       

KEYPRESSED:

          MOV       LINECOUNT,#0                 

          MOV       COUNT,#4

          MOV       A,KEYCODE

LINESCAN: RRC       A

          INC       LINECOUNT

          JNC       KEYIN

          DJNZ      COUNT,LINESCAN                ;列扫描

          

ROWSCAN:  MOV       A,SCANCODE

          RL        A

          INC       ROWCOUNT

          MOV       SCANCODE,A

          CJNE      SCANCODE,#0FEH,LOOP

          AJMP      OUTPUT                        ;行扫描

             

KEYIN:    SETB      KEYFLAG 

          MOV       A,ROWCOUNT

          MOV       B,#4

          MUL       AB

          ADD       A,LINECOUNT

          DEC       A

          MOV       KEYCOUNT,A  

          AJMP      OUTPUT                        ;有按键按下则处理相应得键值存入KEYCOUNT=ROWCOUNT*4+LINCOUNT-1;

          

OUTPUT:   JB        KEYFLAG,NEXT

          MOV       LEDOUT,#0FFH                  ;无按键按下则输出黑屏

          AJMP      START

NEXT:     MOV       DPTR,#DIGITALTABLE       

          MOV       A,KEYCOUNT

          MOVC      A,@A+DPTR

          MOV       LEDOUT,A                      ;有按键按下输出对应的键值

          

KEYRELESE:MOV       KEYMATRIX,SCANCODE

          MOV       KEYCODE,KEYMATRIX

          MOV       A,KEYCODE

          ANL       A,#0FH

          CJNE      A,#0FH,KEYRELESE

          AJMP      START           

          

;********************************************************************************

;子程序介绍：10ms的延时,用于按键消抖

;********************************************************************************          

DEL10MS:  MOV       R7,#20

AA:       MOV       R6,#248

          DJNZ      R6,$

          DJNZ      R7,AA

          RET 

          

DIGITALTABLE:       DB        0C0H, 0F9H, 0A4H, 0B0H, 99H, 92H, 82H, 0F8H

                    DB        80H, 90H, 88H, 83H, 0C6H, 0A1H, 86H, 8EH         

          END

Answer 2

直接去下个键盘记录器就行了，不过一般带病毒，杀软得关闭，至于程序，你看着办，键盘记录器中就有相关程序