求高手把通达信技术指标改为条件选股指标！提示“条件选股公式输出不能超过1”。

Question

A:=MA(-100*(HHV(HIGH,34)-CLOSE)/(HHV(HIGH,34)-LLV(LOW,34)),19);
B:=-100*(HHV(HIGH,14)-CLOSE)/(HHV(HIGH,14)-LLV(LOW,14));
D:=EMA(-100*(HHV(HIGH,34)-CLOSE)/(HHV(HIGH,34)-LLV(LOW,34)),4);

长期线:A+100,COLOR9900FF;
短期线:B+100,COLOR888888;
中期线:D+100,COLORYELLOW,LINETHICK2;

见顶:(REF(中期线,1)>85 AND REF(短期线,1)>85 AND REF(长期线,1)>65) AND CROSS(长期线,短期线),COLORLIBLUE;
顶部区域:(中期线<REF(中期线,1) AND REF(中期线,1)>80) AND (REF(短期线,1)>95 OR REF(短期线,2)>95 ) AND 长期线>60 AND 短期线<83.5
AND 短期线<中期线 AND 短期线<长期线+4,COLORAAAAAA;
顶部:=FILTER(顶部区域,4);

底部区域:(长期线<12 AND 中期线<8 AND (短期线<7.2 OR REF(短期线,1)<5) AND (中期线>REF(中期线,1) OR 短期线>REF(短期线,1)))
OR (长期线<8 AND 中期线<7 AND 短期线<15 AND 短期线>REF(短期线,1)) OR (长期线<10 AND 中期线<7 AND 短期线<1),COLOR4080AA;

STICKLINE( {见顶 OR} 顶部,99,103,20,1 ),COLORRED,LINETHICK2;STICKLINE( 底部区域,-4,0,22,0 ),COLORGREEN;
低位金叉:长期线<15 AND REF(长期线,1)<15 AND 中期线<18 AND 短期线>REF(短期线,1) AND CROSS(短期线,长期线) AND 短期线>中期线 AND (REF(短期线,1)<5 OR REF(短期线,2)<5 ) AND (中期线>=长期线 OR REF( 短期线,1)<1 ),COLOR800080;
STICKLINE( 低位金叉,0,5,11,0 ),COLORRED;
80,COLORCYAN;
20,COLORGREEN;
10,COLORCC6633,LINETHICK2;
90,COLOR9966FF,LINETHICK2;

Answer 1

你没有给出具体的选股的条件。你这个公式可以写出N个选股公式的。

你编辑的时候提示“条件选股公式输出不能超过1”，原因在于选股公式只能有一个输出，
即公式中的 A:= 为一个赋值，长期线: 则为一个输出。就是冒号后面没有等号的就叫输出，冒号后面有等号的就是赋值。
如果你要编辑出选股公式，先把原公式所有的冒号后面加上等号，然后编辑一条符合你条件的输出即可。
（纯手打，抵制复制粘贴）

追问

选股公式是加上下面这个，你帮我修改下啊。
AA:=中期线>长期线;
BB:=中期线>REF(中期线,1);
AA AND BB

追答

因为你给出的选股条件中只用到了中期线和长期线两个参数，则见顶以下的均可不要，多了怕你看不清楚。选股代码如下（在软件商测试通过了，不过选出的股票有点多了）

A:=MA(-100*(HHV(HIGH,34)-CLOSE)/(HHV(HIGH,34)-LLV(LOW,34)),19);
B:=-100*(HHV(HIGH,14)-CLOSE)/(HHV(HIGH,14)-LLV(LOW,14));
D:=EMA(-100*(HHV(HIGH,34)-CLOSE)/(HHV(HIGH,34)-LLV(LOW,34)),4);
长期线:=A+100,COLOR9900FF;
短期线:=B+100,COLOR888888;
中期线:=D+100,COLORYELLOW,LINETHICK2;
AA:=中期线>长期线;
BB:=中期线>REF(中期线,1);
XG:AA AND BB;