EXCEL 求工作天数 每周休息一天 急呀请各位高手们帮帮忙！！！！！

Question

开始上班日期 最后一天工作日 工作天数
2010/12/09 2011/12/31
2011/12/01 2011/12/31
2011/12/15 2011/12/31
2011/01/17 2011/12/31
2011/03/29 2011/12/31
2010/12/31 2011/12/31
2011/12/01 2011/12/31
2011/02/17 2011/12/31
2011/03/01 2011/12/31
2011/03/02 2011/12/31
2011/03/14 2011/12/31
2011/03/18 2011/12/31
2011/03/27 2011/12/31

Answer 1

在单元格C2内输入
=(WEEKDAY(A2)<>1)+SUMPRODUCT(N(MOD(ROW(INDIRECT(A2&":"&B2)),7)>0))
下拉复制公式

解释：
1.按每周日休息一天，如果是周六休息则改为 =(WEEKDAY(A2)<>7)+SUMPRODUCT(N(MOD(ROW(INDIRECT(A2&":"&B2)),7)>0))
2.最后一天是周日，从后向前，每7天休息一日，如果第一天是周日，刚好完整的N个工作周，否则要算多一天周末

Answer 2

设A1="开始上班日期"; B1="最后一天工作日"; C1="天数"; 星期日为休息日；
C2=IF(A2<DATE(2010,12,31),(DATE(2010,12,31)-A2+1)-IF(WEEKDAY(A2)<>1,(WEEKNUM(DATE(2010,12,31))-WEEKNUM(A2)),(WEEKNUM(DATE(2010,12,31))-WEEKNUM(A2))+1)+(B2-DATE(2011,1,1)+1)-(WEEKNUM(B2)-WEEKNUM(DATE(2011,1,1))),IF(A2=DATE(2010,12,31),1+(B2-DATE(2011,1,1)+1)-(WEEKNUM(B2)-WEEKNUM(DATE(2011,1,1))),(B2-A2+1)-IF(WEEKDAY(A2)<>1,(WEEKNUM(B2)-WEEKNUM(A2)),(WEEKNUM(B2)-WEEKNUM(A2))+1)))
求得：天数从上到下分别为：333 27 15 300 239 314 27 273 263 262 252 248 240
解释：weekday(); 返回指定日期对应的星期几，值介于（星期日为1）1-7之间，
weeknum(),返回指定日期在一年中的第几周，值介于（1月1日为第1周)1-53之间；

Answer 3

=(B2-A2+1)-INT((B2-A2+1)/7)

先求出两个工作日期间实际的工作天数(B2-A2+1)
再减去有多少周 INT((B2-A2+1)/7)

上面假设的是每7天放一天假，不够7天的不放假。
————————————
但实际如果是每周日放假，而不是每7天放，上面的会有点误差，比如有人只工作两天，周六和周日，上面算出来是2天，而实际上是1天。
看你需要吧，上面平均的都有几百天，误差小于0.5%

如果要精确的，也不是不行，只是要多花点时间讲究下哪些天是周日。

Answer 4

=INT((B3-(A3-WEEKDAY(A3)))/7)

b3最后，
A3开始。
如果不是星期天休息，需要稍微改一下，给weekday函数制定第二个参数就可以了。

上面是求星期天个数的。
把B3减去A3，再减去上面的结果就是工作天数。

=B3-A3-INT((B3-(A3-WEEKDAY(A3)))/7)

Answer 5

可以考虑用NETWORKDAYS.INTL的函数

=NETWORKDAYS.INTL(B2,A2,11)
其中，第三个元素的应用：
1 或省略 星期六、星期日
2 星期日、星期一
3 星期一、星期二
4 星期二、星期三
5 星期三、星期四
6 星期四、星期五
7 星期五、星期六
11 仅星期日
12 仅星期一
13 仅星期二
14 仅星期三
15 仅星期四
16 仅星期五
17 仅星期六
如果有另外的假期会需要加入[holidays]的值了。这个值是一个集合，函数可以除去这个集合内的日期。