MOV AH,0AH怎么使用，我 MOV AH,0AH INT 21H MOV AH,9 INT 21H MOV AH,4CH INT 21H 我这样不行吗？

Question

我是要将输入的字符再显示出来

Answer 1

MOV AH,0AH
INT 21H
确实是输入一个字符串的指令，可是需要注意的是，使用这个指令的时候需要设置一些东西，否则的话，使用的时候会出错。在这儿解释一下INT 21H里的0Ah功能:输入一个字符串到DS：DX，第一个字节是buffer的大小，第二个字节是实际需要读的字符串的字符个数。而且这个指令不需要在字符串最后加'$'，要使用INT 21H/AH=9号功能打印的话，你必须要在字符串的最后加上'$',而且打印的起始地址为DS：DX+2.
举个例子：

org 100h
mov dx, offset buffer
mov ah, 0ah
int 21h
jmp print
buffer db 10,?, 10 dup(' ')
print:
xor bx, bx
mov bl, buffer[1]
mov buffer[bx+2], '$'
mov dx, offset buffer + 2
mov ah, 9
int 21h
ret
需要注意的就是这些，希望能帮到你

Answer 2

;================================================
ASSUME CS:CODE, DS:DATA
DATA SEGMENT
MSG1 DB 'Input a STR : $'
CRLF DB 0DH, 0AH, '$'
MSG2 DB 'The STR is : $'
;----------------------------------
BUFSIZE DB 50 ;最多可键入50个字符.
ACTLEN DB ? ;实际键入的字符数.
CHARS DB 50 DUP(20H) ;实际键入的字符从此开始存放.
DATA ENDS
;----------------------------------
CODE SEGMENT
START:
MOV AX, DATA
MOV DS, AX

MOV DX, OFFSET MSG1
MOV AH, 9
INT 21H
MOV DX, OFFSET BUFSIZE ;键入缓冲区起始偏移地址送DX
MOV AH, 0AH
INT 21H ;输入字符串并送入缓冲区.
;-----------------------
MOV CL, ACTLEN ;取得输入的字符数.
ADD CL, 0
JNZ OK ;长度不为零就去输出.
JMP EXIT_MAIN
;-----------------------
OK:
MOV DX, OFFSET CRLF
MOV AH, 9
INT 21H
MOV DX, OFFSET MSG2
MOV AH, 9
INT 21H
;-----------------------
XOR CX, CX
MOV CL, ACTLEN ;取得输入的字符数.
MOV DX, OFFSET CHARS ;输入的字符串起始地址送DX
MOV BX, DX ;将字符串首地址送BX
ADD BX, CX ;取到字符串尾地址.
MOV BYTE PTR [BX], '$' ;在字符串尾插$
MOV AH, 09H ;字符串显示功能.
INT 21H ;显示键入的字符串.
EXIT_MAIN:
MOV AH, 4CH
INT 21H ;返回DOS
;----------------------------------
CODE ENDS
END START
;================================================

参考：
http://hi.baidu.com/%D7%F6%B6%F8%C2%DB%B5%C0/blog/item/5adeb99125d2159ba877a4ae.html

追问

呵呵，谢谢哈！不过我觉得程序有点复杂，可不可以弄简单一点～～～

Answer 3

INTn(n:0-255) 功能：称为软中断指令。就一般情况而言，这个指令都是在程序要结束时使用的，故简单地说，这个中断调用指令就是告诉程序当程序里的指令MOV AH,0AH INT 21H执行完毕后要做什么——返回DOS，此时程序就会结束，所以在程序执行到第一个INT 21H语句时即停止编译显示出错。

追问

不是很懂，MOV AH,0AH INT 21H指令不是输入多个字符指令吗

Answer 4

MOV AH,0AH
INT 21H
MOV AH,9
INT 21H
MOV AH,4CH
INT 21H

追问

刚刚运行了，可还是不行，跟我运行的结果是一样的，是不是不支持XP系统呀

追答

我也不太清楚，好久不用这个了。