VFP菜单运行代码是什么

Question

求助

Answer 1

ACTIVATE MENU 命令

显示并激活一个菜单栏。

语法

ACTIVATE MENU MenuBarName
[NOWAIT]
[PAD MenuTitleName]

参数
MenuBarName

指定要激活的菜单栏的名称。

NOWAIT

指定在程序执行时，不等待用户在已激活菜单栏中选择菜单或按 ESC 键，而是继续执行程序。发出 DEACTIVATE MENU 命令后，如果菜单是用 NOWAIT 选项激活的，则程序的执行不返回到 ACTIVATEMENU 命令的下一行命令。

PAD MenuTitleName

指定一个菜单标题名，当激活菜单栏时，选中此菜单标题名。如果不指定菜单标题名，菜单栏激活后，默认激活第一个菜单标题名。

说明

该命令显示并且激活 MenuBarName 指定的菜单栏，需要结合 DEFINE MENU 和 DEFINE PAD 命令使用。

*下面的示例用 ACTIVATE MENU 命令显示并激活一个用户定义的
* 菜单系统。当前系统菜单栏先用 SET SYSMENU SAVE 命令保
* 存在内存中，然后用 SET SYSMENU TO 命令删除所有系统菜
* 单标题。
*用 DEFINE PAD 命令创建两个菜单标题，并且用 DEFINE POPUP
* 为每个菜单标题创建下拉式菜单，然后用 DEFINE BAR 命令在每
* 个菜单上创建菜单项。当选中某个菜单标题后，ON PAD 命令使
* 用 ACTIVATE POPUP 子句激活相应菜单。ACTIVATE MENU
* 命令显示并激活这个选中的菜单栏。

*选择菜单中的某菜单项后，开始执行 CHOICE 过程，CHOICE
* 过程显示了选择的菜单项名和包含此项的菜单名。

*** 把此程序命名为 ACTIMENU.PRG***
CLEAR
SET SYSMENU SAVE
SET SYSMENU TO
ON KEY LABEL ESC KEYBOARD CHR(13)
DEFINE MENU example BAR AT LINE 1
DEFINE PAD convpad OF example PROMPT '\<Conversions' COLOR SCHEME 3 ;
KEY ALT+C, ''
DEFINE PAD cardpad OF example PROMPT 'Card \<Info' COLOR SCHEME 3 ;
KEY ALT+I, ''
ON PAD convpad OF example ACTIVATE POPUP conversion
ON PAD cardpad OF example ACTIVATE POPUP cardinfo
DEFINE POPUP conversion MARGIN RELATIVE SHADOW COLOR SCHEME 4
DEFINE BAR 1 OF conversion PROMPT 'Ar\<ea' ;
KEY CTRL+E, '^E'
DEFINE BAR 2 OF conversion PROMPT '\<Length' ;
KEY CTRL+L, '^L'
DEFINE BAR 3 OF conversion PROMPT 'Ma\<ss' ;
KEY CTRL+S, '^S'
DEFINE BAR 4 OF conversion PROMPT 'Spee\<d' ;
KEY CTRL+D, '^D'
DEFINE BAR 5 OF conversion PROMPT '\<Temperature' ;
KEY CTRL+T, '^T'
DEFINE BAR 6 OF conversion PROMPT 'T\<ime' ;
KEY CTRL+I, '^I'

DEFINE BAR 7 OF conversion PROMPT 'Volu\<me' ;
KEY CTRL+M, '^M'
ON SELECTION POPUP conversion DO choice IN actimenu;
WITH PROMPT( ), POPUP( )
DEFINE POPUP cardinfo MARGIN RELATIVE SHADOW COLOR SCHEME 4
DEFINE BAR 1 OF cardinfo PROMPT '\<View Charges' ;
KEY ALT+V, ''
DEFINE BAR 2 OF cardinfo PROMPT 'View \<Payments' ;
KEY ALT+P, ''
DEFINE BAR 3 OF cardinfo PROMPT 'Vie\<w Users' ;
KEY ALT+W, ''
DEFINE BAR 4 OF cardinfo PROMPT '\-'
DEFINE BAR 5 OF cardinfo PROMPT '\<Charges ' ;
KEY ALT+C, ''
ON SELECTION POPUP cardinfo;
DO choice IN actimenu WITH PROMPT( ), POPUP( )

ACTIVATE MENU example
DEACTIVATE MENU example
RELEASE MENU example EXTENDED
SET SYSMENU TO DEFAULT
ON KEY LABEL ESC
PROCEDURE choice
PARAMETERS mprompt, mpopup
WAIT WINDOW 'You chose ' + mprompt + ' from popup ' + mpopup NOWAIT

Answer 2

1.打开菜单设计器，执行“显示-常规选项”命令，选中“顶层表单”复选框。
2.创建一个表单并将表单的showwindow属性设为2，使其成为顶层表单。
3.在表单的init事件代码中添加调用菜单程序的命令，命令格式如下：
do <菜单程序文件名。mpr> with this [，菜单栏内部名称]
4.在表单的destroy事件代码中添加清除菜单的命令，使得关闭表单时能够清除菜单，释放菜单占用的内存空间，