求VB程序代码 1！+2！……20！的和

Question

求VB高手 帮小弟我解答一下这个程序怎么写，谢谢了

Answer 1

楼上一堆人都不知道精度是会溢出的吗？
你们自己算算20！都多少位了？10！是7位，20！不会低于18位，哪个精度也表示不了这么大数字的精确值，只能用高精度计算。

'高精度乘法
Sub Multiply(src() As Integer, multiplier As Integer)
Dim i As Integer
For i = 0 To UBound(src)
If src(i) <> 0 Then
src(i) = src(i) * multiplier
End If
Next
Carryout src
End Sub
'高精度加法
Sub Add(src() As Integer, adder() As Integer)
Dim i As Integer
For i = 0 To UBound(src)
If i <= UBound(adder) Then
src(i) = src(i) + adder(i)
End If
Next
Carryout src
End Sub
'高精度进位
Sub Carryout(src() As Integer)
Dim i As Integer
For i = 0 To UBound(src)
If src(i) > 9 Then
If i = UBound(src) Then
ReDim Preserve src(i + 1)
End If
src(i + 1) = src(i + 1) + src(i) \ 10
src(i) = src(i) Mod 10
End If
Next
End Sub

'主程序
Sub Main()
Dim i As Integer
Dim MDigit() As Integer
Dim Sum() As Integer
ReDim Sum(0), MDigit(0)
Sum(0) = 0: MDigit(0) = 1
For i = 1 To 20
Multiply MDigit, i
If UBound(MDigit) > UBound(Sum) Then
ReDim Preserve Sum(UBound(MDigit))
End If
Add Sum, MDigit
Next
Dim result As String
For i = UBound(Sum) To 0 Step -1
result = result & Sum(i)
Next
MsgBox result
End Sub

最后结果是：2561327494111820313

Answer 2

Private Sub Command1_Click()
Dim s As Double, s1 As Double, i As Integer
s1 = 1
For i = 1 To 20
s1 = s1 * i
s = s + s1
Debug.Print "i="; i, s1, s
Next i
MsgBox "1！+2！……20！=" & s
End Sub

Answer 3

s(1)=1
sum=1
for i=2 to 20
s(i)=s(i-1)*i
sum=sum+s(i)
next i
应该就可以了

Answer 4

Dim i, k As Integer
Dim sum As Double = 0
Dim s As Double = 1
For i = 1 To 20
For k = 1 To i
s = s * k
Next
sum = sum + s
Next
MessageBox.Show(sum)

Answer 5

简单之极。

Function Exclam(Num) As Single
Dim Chu As Single, Retu As Single
Retu = 1
For Chu = 1 To Num
Retu = Retu * Chu
Next
Exclam = Retu
End Function

Function 计算和() As Single
Dim Jssw As Single, Jia As Single
For Jssw = 1 to 20
Jia=Jia + Exclam(Jssw)
Next
计算和 = Jia
End Function

Private Sub Form_Click()
MsgBox 计算和
End Sub

'单击窗体即可。

Answer 6

s=1
for i =1 to 20
for j= i to 1 step -1
s=s*j
next j
sum=sum+s
next i
print sum