汇编程序 十六进制数转换成ASCII码

Question

题目：将BUF开始的10个单元中两位十六进制数转换成ASCII码，并在屏幕上显示出来。要求码型转换通过子程序HEXASC实现，参数传递采用寄存器传送方式。
另外：
ADD AL,90H
DAA
ADD AL,40H
DAA
这段程序应该怎么理解？

Answer 1

举个例子，6CH，转换成ASCII码，是以十六进制形式显示：6CH，还是以十进制形式显示：108？

; 本程序通过编译，运行正确
Code Segment
Assume CS:Code,DS:Code
; －－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－
; 功能：显示指定地址（Str_Addr）的字符串
; 入口：
; Str_Addr＝字符串地址（要求在数据段）
; 用法: Output Str_Addr
; 用法举例：Output PromptStr
Output MACRO Str_Addr
lea dx,Str_Addr
mov ah,9
int 21h
EndM
; －－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－
; 功能：把AL中的二进制无符号数转换成显式的十进制ASCII
; 入口：AL=二进制数；di=转换后的ASCII保存地址
; 出口：无
HEXASC_Dec Proc Near
push si
push cx
push bx
push di
mov bl,10
xor cx,cx
lea di,@@Temp_Save[3]
cld
@@Divide: xor ah,ah
div bl
or ah,30h
mov [di],ah
dec di
inc cx
test al,0ffh
jnz @@Divide
push di
pop si
inc si
pop di
pop bx
rep movsb
pop cx
pop si
ret
@@Temp_Save db 4 dup(?)
HEXASC_Dec EndP
; －－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－
; 功能：将AL中的低4位二进制数转换成十六进制显示的ASCII码
; 入口：AL
; 出口：AL=转换后的ASCII码
AL_ASCII Proc Near
cmp al,10 ;AL<10?
jb @@To_ASCII ;AL<10，按数字处理
add al,7 ;AL>=10，按大写字母处理
@@To_ASCII: add al,'0' ;转换成相应的数字或大写字母
ret
AL_ASCII EndP
; －－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－
; 功能：将AL中的字节数转换成十六进制显示的ASCII码
; 入口：AL
; 出口：AX=转换后的ASCII码
HEXASC_Hex Proc Near
push cx
mov cx,4
xor ah,ah ;将AH置0
shl ax,cl ;将AX左移4位
shr al,cl ;将AL右移4位
xchg ah,al
call AL_ASCII ;调用子程序，将AL中的值转换成相应的ASCII码
xchg ah,al
call AL_ASCII
xchg ah,al
pop cx
ret
HEXASC_Hex EndP
; －－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－
Translate db '0' ;转换方式（默认：十进制数显示；若要十六进制显示，则改为：1）
BUF db 23,35,46,57,68,79,81,98,119,243
Elements EQU ($-BUF)/Type BUF ;元素个数
Start: push cs
pop ds
push cs
pop es ;使数据段、附加段与代码段同段
cld
lea si,BUF
lea di,Temp_STr
mov cx,Elements
HEX_ASCII: lodsb
.IF Translate == '0'
call HEXASC_Dec
.ELSE
call HEXASC_Hex
stosw
mov al,'H'
stosb
.ENDIF
mov al,','
stosb
loop HEX_ASCII
dec di
mov al,'$'
stosb
Output Temp_STr
Exit_Proc: mov ah,4ch ;结束程序
int 21h
Temp_STr:
Code ENDS
END Start ;编译到此结束
; －－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－
ADD AL,90H
DAA
ADD AL,40H
DAA

十进制数加调整指令DAA(Decimal Adjust After Addition)

该指令是用于调整AL的值，该值是由指令ADD或ADC运算二个压缩型BCD码所得到的结果。压缩型BCD码是一个字节存放二个BCD码，低四位和高四位都是一个BCD码。

其调整规则如下：

* 如果AL的低四位大于9，或标志位AF=1，那么，AL=AL+6，并置AF=1；
* 如果AL的高四位大于9，或CF=1，那么，AL=AL+60H，并置CF=1；
、如果以上两点都不成立，则，清除标志位AF和CF。

经过调整后，AL的值仍是压缩型BCD码，即：二个压缩型BCD码相加，并进行调整后，得到的结果还是压缩型BCD码。

Answer 2

ADD AL,90H
DAA
ADC AL,40H
DAA

这段程序，是把十六进制数转换成ASCII码。

显示10个两位十六进制数的完整程序如下。